XSLT mod 检查大数

Question

我正在尝试在 XSLT 1.0 中对 17 位数字进行模数 11 检查。然而，它似乎总是给出错误的输出。

我能找到的关于此的唯一信息位于

我过去曾使用 Luhn 检查器的 XSLT 模板，我意识到这与模数检查的工作方式不同，但我想知道是否有人知道可以计算大数模数的 XSLT 模板？

Answer 1

有一个纯 XSLT 1.0 解决方案，可以计算任意大小的整数 $n 的 $n mod 11：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <xsl:call-template name="mod11"/>
 </xsl:template>

 <xsl:template name="mod11">
  <xsl:param name="pN" select="."/>

  <xsl:choose>
   <xsl:when test="not($pN > 9999999999999999)">
     <xsl:value-of select="$pN mod 11"/>
   </xsl:when>
   <xsl:otherwise>
      <xsl:variable name="vLen" select="string-length($pN)"/>

      <xsl:variable name="vLen1" select="$vLen -1"/>

      <xsl:variable name="vPart1" select=
          "substring($pN, 1, $vLen1)"/>

      <xsl:variable name="vPart2" select=
          "substring($pN, $vLen1 +1)"/>

      <xsl:variable name="vMod1">
       <xsl:call-template name="mod11">
         <xsl:with-param name="pN" select="$vPart1"/>
       </xsl:call-template>
      </xsl:variable>

      <xsl:variable name="vMod2" select="$vPart2 mod 11"/>

      <xsl:value-of select="(10*$vMod1 + $vMod2) mod 11"/>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

应用此转换时在以下 XML 文档上：

<t>12345678901234567</t>

生成所需的正确结果 (12345678901234567 mod 11)：

9

请注意：

1. 这个解决方案可以很容易地推广到计算任何整数$m的$n mod $m——只需将$m作为第二个参数。

2. 另一个概括是作为参数传递限制，超过该限制就无法使用 mod 运算符直接计算 $n mod $m 。当使用 XSLT 2.0 并将 $n 作为 xs:integer 或 xs:decimal 时，这可能很有用。

3. 另一种替代方法是使用 Saxon.NET XSLT 2.0 处理器或任何其他实现大整数算术的 XSLT 2.0 处理器。那么解决方案就是使用 mod 运算符：

....

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
     <xsl:value-of select="xs:integer(.) mod 11"/>
 </xsl:template>
</xsl:stylesheet>

当此转换与 Saxon 9.1.07 应用于同一个 XML 文档（如上）时，会产生相同的正确结果：

9

Answer 2

这是因为在 MSXML 中，数字类型相当于 .NET Double 数据类型，其精度为 15-16 位。
尝试这个示例：

double d = 123456789012345678;
Console.WriteLine("{0:f}", d);
Console.WriteLine("{0:f}", d + 1);
Console.WriteLine("{0:f}", d % 3);

long l = 123456789012345678;
Console.WriteLine(l);
Console.WriteLine(l + 1);
Console.WriteLine(l % 3);

输出：

123456789012346000,00
123456789012346000,00
2,00
123456789012345678
123456789012345679
0

我认为您可以使用 C# 或 JScript 扩展 XSLT，因为 MSXML 支持此功能。

参考： http://msdn.microsoft.com/ en-us/library/533texsx(v=VS.100).aspx, http://msdn.microsoft.com/en-us/magazine/cc302079.aspx