DOS 批处理 FOR 循环与 FIND.exe 正在删除空白行？

Question

即使我使用 TYPE.exe 命令转换文件以确保文件是 ASCII 以便 FIND 命令与文件兼容，此 DOS 批处理脚本也会删除文件中的空行并且不显示文件中的空行。谁能告诉我如何使这个脚本包含空行？

@ECHO off
FOR /F "USEBACKQ tokens=*" %%A IN (`TYPE.exe "build.properties" ^| FIND.exe /V ""`) DO (
  ECHO --%%A--
)
pause

Answer 1

这是 FOR /F 的设计行为 - 它永远不会返回空行。解决方法是使用 FIND 或 FINDSTR 在行前添加行号。如果您可以保证没有行以行号分隔符开头，那么您只需设置适当的分隔符并保留标记 1* 但仅使用第二个标记。

::preserve blank lines using FIND, assume no line starts with ]
::long lines are truncated
for /f "tokens=1* delims=]" %%A in ('type "file.txt" ^| find /n /v ""') do echo %%B

::preserve blank lines using FINDSTR, assume no line starts with :
::long lines > 8191 bytes are lost
for /f "tokens=1* delims=:" %%A in ('type "file.txt" ^| findstr /n "^"') do echo %%B

::FINDSTR variant that preserves long lines
type "file.txt" > "file.txt.tmp"
for /f "tokens=1* delims=:" %%A in ('findstr /n "^" "file.txt.tmp"') do echo %%B
del "file.txt.tmp"

我更喜欢 FINDSTR - 它更可靠。例如，FIND 可以截断长行，而 FINDSTR 则不能，只要它直接从文件中读取即可。通过管道或重定向从 stdin 读取时，FINDSTR 确实会丢弃长行。

如果文件可能包含以分隔符开头的行，则需要保留带有行号前缀的整行，然后使用搜索和替换来删除行前缀。当将 %%A 传输到环境变量时，您可能希望关闭延迟扩展，否则任何！将会被损坏。但稍后在循环中，您需要延迟扩展来进行搜索和替换。

::preserve blank lines using FIND, even if a line may start with ]
::long lines are truncated
for /f "delims=" %%A in ('type "file.txt" ^| find /n /v ""') do (
  set "ln=%%A"
  setlocal enableDelayedExpansion
  set "ln=!ln:*]=!"
  echo(!ln!
  endlocal
)

::preserve blank lines using FINDSTR, even if a line may start with :
::long lines >8191 bytes are truncated
for /f "delims=*" %%A in ('type "file.txt" ^| findstr /n "^"') do (
  set "ln=%%A"
  setlocal enableDelayedExpansion
  set "ln=!ln:*:=!"
  echo(!ln!
  endlocal
)

::FINDSTR variant that preserves long lines
type "file.txt" >"file.txt.tmp"
for /f "delims=*" %%A in ('findstr /n "^" "file.txt.tmp"') do (
  set "ln=%%A"
  setlocal enableDelayedExpansion
  set "ln=!ln:*:=!"
  echo(!ln!
  endlocal
)
del "file.txt.tmp"

如果您不需要担心将文件转换为 ASCII，那么删除管道并让 FIND 或 FINDSTR 打开指定为参数的文件或通过重定向会更有效。

还有另一种解决方法可以在读取过程中完全绕过 FOR /F。看起来很奇怪，但效率更高。使用延迟扩展没有任何限制，但不幸的是它还有其他限制。

1) 行必须以结束； （如果进行 TYPE 文件转换，这不会成为问题）

2) 行的长度必须 <= 1021 字节（忽略）

3) 从每行中删除任何尾随控制字符。

4）它必须从文件中读取 - 你不能使用管道。因此，在您的情况下，您将需要使用临时文件来进行 ASCII 转换。

setlocal enableDelayedExpansion
type "file.txt">"file.txt.tmp"
for /f %%N in ('find /c /v "" ^<"file.txt.tmp"') do set cnt=%%N
<"file.txt.tmp" (
  for /l %%N in (1 1 %cnt%) do(
    set "ln="
    set /p "ln="
    echo(!ln!
  )
)
del "file.txt.tmp"

Answer 2

我编写了一个非常简单的程序，当用于此目的时，它可以替代 FIND 和 FINDSTR 命令。我的程序叫PIPE.COM，它只是在空行中插入一个空格，所以所有的行都可以直接用FOR命令处理，不需要进一步的调整（只要因为插入的空格不关心）。这里是：

@ECHO off
if not exist pipe.com call :DefinePipe
FOR /F "USEBACKQ delims=" %%A IN (`pipe ^< "build.properties"`) DO (
  ECHO(--%%A--
)
pause
goto :EOF

:DefinePipe
setlocal DisableDelayedExpansion
set pipe=´)€ì!Í!ŠÐŠà€Ä!€ü.t2€ü+u!:æu8²A€ê!´#€ì!Í!².€ê!´#€ì!Í!²+€ê!´#€ì!Í!Šò€Æ!´,€ì!Í!"Àu°´LÍ!ëÒ
setlocal EnableDelayedExpansion
echo !pipe!>pipe.com
exit /B

编辑：附录作为新评论的答案

:DefinePipe 子例程中的代码创建一个名为 pipeline.com 的 88 字节程序，它基本上执行与此等效的过程伪批处理代码：

set "space= "
set line=
:nextChar
   rem Read just ONE character
   set /PC char=
   if %char% neq %NewLine% (
      rem Join new char to current line
      set line=%line%%char%
   ) else (
      rem End of line detected
      if defined line (
         rem Show current line
         echo %line%
         set line=
      ) else (
         rem Empty line: change it by one space
         echo %space%
      )
   )
goto nextChar

这样，输入文件中的空行会被带有一个空格的行更改，因此 FOR /F 命令不再省略它们。正如我在回答中所说，“只要插入的空间不关心”，这就有效。

请注意，pipe.com 程序无法在 64 位 Windows 版本中运行。

安东尼奥

Answer 3

输出行包括空行

这是我为自己使用而开发的方法。

将代码保存为批处理文件，例如 SHOWALL.BAT 并将源文件作为命令行参数传递。

输出可以被重定向或通过管道传输。

@echo off

for /f "tokens=1,* delims=]" %%a in ('find /n /v "" ^< "%~1"') do echo.%%ba

exit /b

示例：

showall source.txt

showall source.txt > destination.txt

showall source.txt | FIND "string"

一个奇怪的地方是包含'^<' （重定向）而不是仅仅执行以下操作：

for /f "tokens=1,* delims=]" %%a in ('find /n /v "" "%~1"') do echo.%%ba

通过省略重定向，将输出前导空行。

Answer 4

感谢 dbenham，这可行，尽管与他的建议略有不同：

::preserve blank lines using FIND, no limitations
for /f "USEBACKQ delims=" %%A in (`type "file.properties" ^| find /V /N ""`) do (
  set "ln=%%A"
  setlocal enableDelayedExpansion
  set "ln=!ln:*]=!"
  echo(!ln!
  endlocal
)

Answer 5

正如上述问题的 this 答案中提到的，默认情况下使用 for 似乎不会跳过行/f（至少）Windows XP（社区 - 请通过在您的 Windows 版本和服务包上测试以下批处理命令来更新此答案） 。

   编辑：根据Jeb的下面的评论，似乎 ping 命令，至少在 Windows XP 中是
   导致 for /f 产生 而不是空行（如果有人具体知道原因，会
如果他们可以更新此答案或评论，我们将不胜感激）。

   作为解决方法，似乎是第二个默认分隔标记（示例中的 / %%b）
   返回为空白，这适用于我通过“父级”消除空白行的情况
   if 以 for /f 开头的第二个标记为条件，如下所示：

   for /f "tokens=1,2*" %%a in ('ping -n 1 google.com') do (
      if not "x%%b"=="x" (
         {do things with non-blank lines}
      )
   )

使用下面的代码：

@echo off
systeminfo | findstr /b /c:"OS Name" /c:"OS Version" 
echo.&echo.
ping -n 1 google.com
echo.&echo.
for /f %%a in ('ping -n 1 google.com') do ( echo "%%a" )
echo.&echo.&echo --------------&echo.&echo.
find /?
echo.&echo.
for /f %%a in ('find /?') do ( echo "%%a" )
echo.&echo.
pause

.... 以下是我在 Windows XP、Windows 7 和 Windows 2008 上看到的，这是唯一的三个版本我可以随时访问的 Windows 服务包：