使用换行符将文件从 AS 加载到 cl_gui_textedit

Question

我想在 cl_gui_textedit 组件内显示一个带有换行符的文件，这给我带来了问题。

我使用以下代码来初始化组件

  DATA: lo_c_errorviewer TYPE REF TO cl_gui_custom_container.

  CREATE OBJECT lo_c_errorviewer
    EXPORTING
        container_name = 'C_ERROR_MSG'.

  CREATE OBJECT go_error_textedit
    EXPORTING parent = lo_c_errorviewer.

  go_error_textedit->set_toolbar_mode( 0 ).
  go_error_textedit->set_statusbar_mode( 0 ).

在使用 iXML 包进行一些 XML 处理之后，文件的二进制数据如下所示：

types: begin of xml_line,
        data(256) type x,
       end of xml_line.

data:  xml_table type table of xml_line,
       xml_size  type i.

ostream = streamFactory->create_ostream_itable( xml_table ).
document->render( ostream = ostream  recursive = 'X' ).
xml_size = ostream->get_num_written_raw( ).

如果我是对的，这应该包含换行符。 ostream 对象默认打开“漂亮打印”。

我搜索了参考文献，传递信息的唯一方法是通过

call method <c_textedit_control> - > set_text_as_stream

它需要一个字符的“标准表”。如何转换数据或将其传递给组件？

Answer 1

如果直接将 XML 文档呈现为 STRING，然后将其发送到 CL_GUI_TEXTEDIT 控件，会更容易：

data xmlstring type string.
data ostream type ref to if_ixml_ostream.
ostream = streamfactory->create_ostream_cstring( xmlstring ).
document->render( ostream = ostream recursive = 'X' ).
...
data textedit type ref to cl_gui_textedit.
create object textedit
  exporting
    parent = container.
textedit->set_textstream( xmlstring ).

如果您必须渲染为二进制数据，那么我建议您使用 XSTRING：

data xmlxstring type xstring.
data ostream type ref to if_ixml_ostream.
ostream = streamfactory->create_ostream_xstring( xmlxstring ).
document->render( ostream = ostream recursive = 'X' ).

然后您可以使用 SAP 提供的 CL_ABAP_CONV_IN_CE 类将二进制数据转换为字符串：

data converter type ref to cl_abap_conv_in_ce.
converter = cl_abap_conv_in_ce=>create( input = xmlxstring ).
data xmlstring type string.
converter->read( importing data = xmlstring ).

您可以将其发送到 CL_GUI_TEXTEDIT 控件：

data textedit type ref to cl_gui_textedit.
create object textedit
  exporting
    parent = container.
textedit->set_textstream( xmlstring ).

请注意，如果遇到编码问题，您可以在渲染之前在 ostream 对象上设置编码，并且转换器对象允许您在创建它时指定编码。