Delphi 2007 中的 AsyncCall

Question

我基本上想要的是启动 AsyncCall并继续加载我的代码。我的接口部分消耗了大量时间（600+毫秒），我想在独立线程中加载此代码。

我尝试使用 AsyncCall 来做这样的事情：

procedure Load;
begin
...
end;

initialization
  AsyncCall(@Load, []); // or LocalAsyncCall(@Load)

但是，这个 Load 过程实际上是在主线程中启动的，而不是在新创建的线程中启动的。如何强制将 Load 过程加载到 MainThread 以外的任何线程中？

我可以创建 TThread 并执行此操作，但我想强制 AsyncCall 或 LocalAsyncCall 或 AsyncCall 中的任何内容 库才能工作。

感谢您的帮助。

Answer 1

你尝试过这样的事情吗？：

procedure Load;
begin
  if GetCurrentThreadId <> MainThreadID then
    Beep;
end;

var a: IAsyncCall;

initialization
  a := AsyncCall(@Load, []);
  a.ForceDifferentThread;

ForceDifferentThread() 告诉 AsyncCalls 分配的函数必须
不在当前线程中执行。

Answer 2

问题是您的代码没有保留由 AsyncCall 函数返回的 IAsyncCall 接口。

AsyncCall(@Load, []);
//AsyncCall returns an IAsyncCall interface,
//but this code does not take a reference to it

因此，一旦初始化部分完成，返回的接口的引用计数就会减为零。因此，这释放了实现执行此操作的接口的对象：

destructor TAsyncCall.Destroy;
begin
  if FCall <> nil then
  begin
    try
-->   FCall.Sync; // throw raised exceptions here
    finally
      FCall.Free;
    end;
  end;
  inherited Destroy;
end;

关键行是对 Sync 的调用，它强制异步调用执行完成。所有这些都发生在主线程中，这解释了您报告的行为。

---

解决方案是，您只需将 IAsyncCall 接口存储在变量中即可使其保持活动状态。

var
  a: IAsyncCall;

initialization
  a := AsyncCall(@Load, []);

在实际代码中，您需要确保在运行依赖于 Load 的任何代码之前已完成 Load。当您的程序达到需要调用 Load 的程度时，它必须在 IAsyncCall 接口上调用 Sync。

所以你可以这样写。

unit MyUnit;

interface

procedure EnsureLoaded;

implementation

uses
  AsyncCalls;

....

procedure Load;
begin
  ....
end;

var
  LoadAsyncCall: IAsyncCall;

procedure EnsureLoaded;
begin
  LoadAsyncCall := nil;//this will effect a call to Sync
end;

initialization
  LoadAsyncCall := AsyncCall(@Load, []);

end.

来自需要 Load 运行的其他单元的调用 EnsureLoaded。或者，也可以从 MyUnit 导出的依赖于 Load 运行的任何方法调用 EnsureLoaded。后一种选择具有更好的封装性。