有没有办法为 gradle 中新创建的源集指定依赖项？

Question

在 gradle 中，我为服务测试创建了一个新的 sourceSet ，如下所示：

sourceSets{
    servicetest{
        java.srcDirs = [//path to servicetests]
    }
}

此源集依赖于 TestNG，因此我希望通过执行以下操作来拉低依赖关系：

dependencies{
    servicetest(group: 'org.testng', name: 'testng', version: '5.8', classifier: 'jdk15')
}

不幸的是，这会返回错误。有没有办法声明特定 sourceSet 的依赖关系，或者我运气不好？

Answer 1

最新的 Gradle 版本会自动为每个源集“foo”创建并连接配置“fooCompile”和“fooRuntime”。

如果您仍在使用旧版本，您可以声明自己的配置并将其添加到源集的compileClasspath或runtimeClasspath中。像这样的东西：

configurations {
    serviceTestCompile
}

sourceSets {
    serviceTest {
        compileClasspath = configurations.serviceTestCompile
    }
}

dependencies {
    serviceTestCompile "org.testng:testng:5.8"
}

Answer 2

以下适用于 Gradle 1.4。

apply plugin: 'java'

sourceCompatibility = JavaVersion.VERSION_1_6

sourceSets {
    serviceTest {
        java {
            srcDir 'src/servicetest/java'
        }
        resources {
            srcDir 'src/servicetest/resources'
        }
        compileClasspath += sourceSets.main.runtimeClasspath
    }
}

dependencies {
    compile(group: 'org.springframework', name: 'spring', version: '3.0.7')

    serviceTestCompile(group: 'org.springframework', name: 'spring-test', version: '3.0.7.RELEASE')
    serviceTestCompile(group: 'org.testng', name:'testng', version:'6.8.5')
}


task serviceTest(type: Test) {
    description = "Runs TestNG Service Tests"
    group = "Verification"
    useTestNG()
    testClassesDir = sourceSets.serviceTest.output.classesDir
    classpath += sourceSets.serviceTest.runtimeClasspath
}