在该函数内调用该函数，然后停止循环 - 启动和停止停止功能

Question

我正在让一个角色行走。这段代码将使他向右摆动，完成后将触发他向左摆动，然后再次调用该函数以继续循环。

我可以通过调用该函数使循环正常工作，但如何停止该函数？ 我也想稍后再调用它。有没有办法启动和停止函数？

function wobble()
{
    var ws  = .1;
    var dis = 1;

    var WobbleRight:Tween = new Tween(Beau, "rotation", Strong.easeIn, Beau.rotation, dis, ws, true);
    WobbleRight.addEventListener(TweenEvent.MOTION_FINISH, WobbleL);
    function WobbleL(e:TweenEvent):void 
         {
        var WobbleLeft:Tween = new Tween(Beau, "rotation", Strong.easeIn,Beau.rotation, -dis, ws, true);
        WobbleLeft.addEventListener(TweenEvent.MOTION_FINISH, WobbleR);
            function WobbleR(e:TweenEvent):void 
            {
            wobble();
            }

        }
}
wobble();

---

或者有更好的方法吗？我想启动补间并通过调用函数来停止它们。开启步行并关闭。 - 非常感谢！

Answer 1

试试这个代码。请注意 Tween 的重用方式，以及在 Tween 动作重新启动时 begin 位置重置为 Beau.rotation。另外，不要将您的函数嵌入到另一个函数中。

（我强调了这个动作并放慢了速度进行测试）：

import fl.transitions.TweenEvent;
import fl.transitions.Tween;
import fl.transitions.easing.Strong;

var ws  = 1;
var dis = 10;

var WobbleRight:Tween;
var WobbleLeft:Tween;

this.addEventListener(MouseEvent.CLICK, toggleWobble);

function startWobble():void 
{
    WobbleR(null);
}

function WobbleL(e:TweenEvent):void 
{
    if (!WobbleLeft) 
    {
        WobbleLeft = new Tween(Beau, "rotation", Strong.easeIn, Beau.rotation, -dis, ws, true);
        WobbleLeft.addEventListener(TweenEvent.MOTION_FINISH, WobbleR);
    } else {
        WobbleRight.begin = Beau.rotation;
        WobbleLeft.start();
    }
}


function WobbleR(e:TweenEvent):void 
{
    if (!WobbleRight) 
    {
        WobbleRight = new Tween(Beau, "rotation", Strong.easeIn, Beau.rotation, dis, ws, true);
        WobbleRight.addEventListener(TweenEvent.MOTION_FINISH, WobbleL);
    } else {
        WobbleRight.begin = Beau.rotation;
        WobbleRight.start();
    }
}

function toggleWobble(e:MouseEvent):void 
{
    if( WobbleRight && WobbleRight.isPlaying ) {
        WobbleRight.stop();
    } else if ( WobbleLeft && WobbleLeft.isPlaying ) {
        WobbleLeft.stop();
    } else {
        startWobble();
    }
}

startWobble();

Answer 2

你想通过什么方式停止摇晃？摆动几次后是否会停止，或者用户应该单击按钮？

如果你想在几次后停止摆动，那么你应该使用计时器。在计时器事件上调用 wobble()。如果用户要停止摆动，则只需使用触发器 isStopped。如果 isStopped 设置为 true，则从 wobble() 返回。