就任何其他不同环境下这个简单的本地化性能测试得出的结果的有效性寻求第二意见

Question

我的设置：

• 操作系统：Windows 7 SP1（32 位）
• RAM：4 Go
• 处理器：Intel Pentium D 3.00 GHz
• Delphi XE

我的简单测试：

我执行了运行以下命令的测试程序：

program TestAssign;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Diagnostics;

type
  TTestClazz = class
  private
    FIntProp: Integer;
    FStringProp: string;
  protected
    procedure SetIntProp(const Value: Integer);
    procedure SetStringProp(const Value: string);
  public
    property  IntProp: Integer   read FIntProp write SetIntProp;
    property  StringProp: string read FStringProp write SetStringProp;
  end;

{ TTestClazz }

procedure TTestClazz.SetIntProp(const Value: Integer);
begin
  if FIntProp <> Value then
    FIntProp := Value;
end;

procedure TTestClazz.SetStringProp(const Value: string);
begin
  if FStringProp <> Value then
    FStringProp := Value;
end;

var
  i, j: Integer;
  stopw1, stopw2 : TStopwatch;
  TestObj: TTestClazz;

begin
  ReportMemoryLeaksOnShutdown := True;
  //
  try
    TestObj := TTestClazz.Create;
    //
    try
      j := 10000;

      while j <= 100000 do
      begin
        ///
        /// assignement
        ///
        stopw1 :=  TStopwatch.StartNew;
        for i := 0 to j do
        begin
          TestObj.FIntProp := 666;
          TestObj.FStringProp := 'Hello';
        end;
        stopw1.Stop;

        ///
        /// property assignement using Setter
        ///
        stopw2 := TStopwatch.StartNew;
        for i := 0 to j do
        begin
          TestObj.IntProp := 666;
          TestObj.StringProp := 'Hello';
        end;
        stopw2.Stop;

        ///
        /// Log results
        ///

        Writeln(Format('Ellapsed time for %6.d loops: %5.d %5.d', [j, stopw1.ElapsedMilliseconds, stopw2.ElapsedMilliseconds]));

        //
        Inc(j, 5000);
      end;
      //
      Writeln('');
      Write('Press Return to Quit...');

      Readln;
    finally
      TestObj.Free
    end
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

我的（临时）结论：

看来：

• 在某些条件下使用具有属性的 Setter 是值得的
• 调用方法和执行条件测试的开销比赋值花费的时间更少。

我的问题：

这些发现在任何其他不同环境下有效还是仅在本地环境下有效（例外）？

Answer 1

我会提出以下意见：

1. 是否使用 setter 的决定应该基于代码维护、正确性、可读性等因素，而不是性能。
2. 您的基准测试完全不合理，因为 if 语句每次都计算为 False。设置属性的现实世界代码可能会在设置器运行的合理时间内修改属性。
3. 我希望对于许多现实世界的例子，设置器在没有相等测试的情况下会运行得更快。如果该测试每次都评估为True，那么显然，如果没有它，代码会更快。
4. 整数设置器实际上是免费的，并且实际上设置器比直接字段访问慢。
5. 时间花在了字符串属性上。由于 if 测试的优化，如果可能的话，可以避免字符串赋值代码，从而带来一些真正的性能优势。
6. 如果将 setter 内联，它们会更快，但速度不会太快。

我相信任何现实世界的代码永远无法检测到任何这些性能差异。实际上，瓶颈将是获取传递给设置器的值，而不是在设置器中花费的时间。

这种if保护有价值的主要情况是属性修改成本高昂。例如，可能涉及发送 Windows 消息或访问数据库。对于由字段支持的财产，您可能可以接受或离开它。

---

在评论中的讨论中，过早优化想知道为什么比较 if FStringProp <> Value 比赋值 FStringProp := Value 更快。我进一步调查了一下，发现情况并不像我最初想象的那样。

事实证明 if FStringProp <> Value 由对 System._UStrEqual 的调用控制。传递的两个字符串实际上不是相同的引用，因此必须比较每个字符。然而，这段代码经过了高度优化，最重要的是只有 5 个字符可供比较。

对 FStringProp := Value 的调用会转到 System._UStrAsg，并且由于 Value 是一个具有负引用计数的文字，因此必须使用一个全新的字符串被制作。 Pascal 版本的代码如下所示：

procedure _UStrAsg(var Dest: UnicodeString; const Source: UnicodeString); // globals (need copy)
var
  S, D: Pointer;
  P: PStrRec;
  Len: LongInt;
begin
  S := Pointer(Source);
  if S <> nil then
  begin
    if __StringRefCnt(Source) < 0 then   // make copy of string literal
    begin
      Len := __StringLength(Source);
      S := _NewUnicodeString(Len);
      Move(Pointer(Source)^, S^, Len * SizeOf(WideChar));
    end else
    begin
      P := PStrRec(PByte(S) - SizeOf(StrRec));
      InterlockedIncrement(P.refCnt);
    end;
  end;
  D := Pointer(Dest);
  Pointer(Dest) := S;
  _UStrClr(D);
end;

其中的关键部分是对 _NewUnicodeString 的调用，它当然会调用 GetMem。对于堆分配比 5 个字符的比较慢得多，我一点也不感到惊讶。

Answer 2

将 'Hello' const 放入变量中并使用它进行设置，然后再次进行测试