使用Delete从方阵中删除行和列

Question

给定：方阵，list表示要删除的行的索引，同时也表示要删除的列的索引（因为是方阵，所以只需要一个list）。

输出：方阵，删除列表中的行和列。

假设有效的索引列表。

这是一个例子

所以上面说要删除第二行和第四行，以及第二行和第四列。

我不知道如何使用 Delete[] 同时删除行和列，而且我真的不想为要删除的每个单独元素索引创建一个列表。

但我可以使用 Delete 来删除行。

下面是我解决这个问题的方法，我首先删除行，然后转置矩阵，然后删除新矩阵的行（这将是原始矩阵的列），然后将结果转置回去以获得我想要的结果。

像这样：

a = {{0, 5, 2, 3, 1, 0}, {4, 3, 2, 5, 1, 3}, {4, 1, 3, 5, 3, 2}, {4, 
    4, 1, 1, 1, 5}, {3, 4, 4, 5, 3, 3}, {5, 1, 4, 5, 2, 0}};
del = {{2}, {4}};
a = Delete[a, del];
a = Delete[Transpose[a], del];
(a = Transpose[a]) // MatrixForm

我的问题：是否有更短的方法使用删除（或另一种专家技巧）以更好的方式做到这一点？

谢谢

Answer 1

如果您想删除相同的索引列和行，我将使用 Part。例如，要查看删除了第 2 行和第 4 行的 a：

a[[{1, 3, 5, 6}, {1, 3, 5, 6}]] // MatrixForm

为了使其更通用，您可以创建一些将 DeleteCases 与 Range 组合起来的内容> 和列/行索引列表，但在没有进一步信息的情况下，我还没有尝试这样做。

编辑

remove[a_?MatrixQ, pos_List] := Module[{tmp, length = Length[a]},

  tmp = DeleteCases[Range[length], Alternatives @@ pos];

  a[[tmp, tmp]]

  ]

remove[a,{2,4}]
{{0, 2, 1, 0}, {4, 3, 3, 2}, {3, 4, 3, 3}, {5, 4, 2, 0}}

编辑2

remove2[a_?MatrixQ, pos_List] := Module[{tmp, length = Length[a]},

  tmp = Complement[Range[length], pos];

  a[[tmp, tmp]]

  ]

remove2[a,{2,4}]
{{0, 2, 1, 0}, {4, 3, 3, 2}, {3, 4, 3, 3}, {5, 4, 2, 0}}

针对您的现实问题测试这两个内容。

Answer 2

这应该是比双转置方法更快的删除行的方法：

a = {{0, 5, 2, 3, 1, 0},
     {4, 3, 2, 5, 1, 3},
     {4, 1, 3, 5, 3, 2},
     {4, 4, 1, 1, 1, 5},
     {3, 4, 4, 5, 3, 3},
     {5, 1, 4, 5, 2, 0}};
del = {{2}, {4}};

a = MapThread[Delete, {a, Table[del, {Length[a]}]}]

时间各不相同，但在这个有些人为的示例中它更快：

a = Table[RandomReal[], {1000}, {10000}];
del = Map[List, Union[Table[RandomInteger[{1, 10000}], {100}]]];
Timing[Transpose[Delete[Transpose[a], del]];]

{0.25，Null}

Timing[MapThread[Delete, {a, Table[del, {Length[a]}]}];]

（0.125，Null}

Answer 3

这比 Part 方法效率低得多，但我发现它更透明，而且有时更重要。

ReplacePart[a, {{2}, {4}, {_, 2}, {_, 4}} :> Sequence[]]

Answer 4

您当然可以使用 Drop:

Drop[a, {2, 4, 2}, {2, 4, 2}] // MatrixForm

我不知道这有多普遍，但也许它会帮助您朝着正确的方向前进。