从 txtfile vb.net 获取数据

Question

我正在寻找一种从 txt 文件读取数据的方法。文本文件具有这种结构（固定长度字段）：

0000       AAAAAA     BBBBBB   CCCCCCCC
0000       JJJJJJ     III      RRRRRR
1111       XXXX       YYYYYYYY ZZZZZZZZ
1111       WW         PPPPPPPP ZZZZZZZZ
1111       XXXX       YYYYYYYY ZZZZZZZZ
2222       XXXX       YYYYYYYY ZZZZZZZZ
...

我必须按第一个字段将它们分组，在某种字典列表列表或类似的列表中。对于这个特定的示例，解决方案是：

id(list): 0000,1111,2222.....
(content)List: 0000
    field1(list): AAAAAA,JJJJJJ
    field2(list): BBBBBB,III
    field3(list): CCCCCCCC,RRRRRR
(content)List: 1111
    field1(list): XXXX,WW,XXXX
    field2(list): YYYYYYYY,PPPPPPPP,YYYYYYYY 
    field3(list): ZZZZZZZZ,ZZZZZZZZ,ZZZZZZZZ
(content)List: 2222
    field1(list): XXXX...
    field2(list): YYYYYYYY...
    field3(list): ZZZZZZZZ...

现在我将整个 txt 存储在字符串列表中（每行一个）。

我怎样才能在 vbnet 中做到这一点？您认为有更好的方法来解决这个问题吗？

谢谢，祝你新年快乐

Answer 1

您可以使用 LINQ 创建一个以第一列作为键的字典：

Dim fileName = "C:\Temp\Test.txt"
Dim allLines = IO.File.ReadAllLines(fileName)

Dim query = From line In allLines
        Select Columns = Microsoft.VisualBasic.Split(line, vbTab)
        Select ID = If(Columns.Count <> 0, Columns(0), " "), Values = Columns.Skip(1).ToList
        Group By ID Into Group
        Select ID, Group

' create a Dictionary from the LINQ-Query '
Dim dict = query.ToDictionary(Function(grp) (grp.ID))
' iterate all Dictionary-Entries '
For Each entry In dict
    Dim key = entry.Key ' f.e 0000 
    For Each grp In entry.Value.Group
        Dim id = grp.ID ' f.e 0000 (can repeat how we see in your example) '
        Dim values As List(Of String) = grp.Values
        ' f.e. (0) "AAAAAA"  (1) "BBBBBB" (2) "CCCCCCCC" '
    Next
Next

---

如果您不熟悉 LINQ（并且您正在使用 .NET 4.0），我建议使用 List(Of Tuple(Of String, List(Of String))) 因为重复项是允许（字典是没有选项）。

Dim data = New List(Of Tuple(Of String, List(Of String)))
For Each line In allLines
    Dim Columns = Microsoft.VisualBasic.Split(line, vbTab)
    Dim ID = If(Columns.Count <> 0, Columns(0), "[empty-line]")
    data.Add(Tuple.Create(ID, Columns.ToList))
Next
' iterate the collection and read values '
For Each item In data
    Dim ID = item.Item1
    Dim Columns = item.Item2
Next

http://msdn.microsoft.com/en-us/library/system .tuple.aspx

---

编辑：

如果您因为没有使用 .NET 4.0 而无法使用元组，请尝试按照“oldschool”方法创建 Dictionary(Of String, List （的列表（字符串）））。

它产生确切的期望结果（与其他方式不同，因为到目前为止我有点误解了您的要求）：

Dim allLines = IO.File.ReadAllLines(fileName)
Dim data As New Dictionary(Of String, List(Of List(Of String)))
For Each line In allLines
    Dim cols = line.Split(ControlChars.Tab)
    Dim ID As String
    If cols.Length <> 0 AndAlso cols(0).Length <> 0 Then
        ID = cols(0)
        If data.ContainsKey(ID) Then
            Dim columnLists = data(ID)
            For colIndex As Int32 = 1 To cols.Length - 1 'skip first(id)-column
                If columnLists.Count >= colIndex Then
                    Dim columnList = columnLists(colIndex - 1)
                    columnList.Add(cols(colIndex))
                Else
                    Dim newColumnList As New List(Of String)
                    newColumnList.Add(cols(colIndex))
                    columnLists.Add(newColumnList)
                End If
            Next
        Else
            Dim columnLists = New List(Of List(Of String))
            For colIndex As Int32 = 1 To cols.Length - 1 'skip first(id)-column
                Dim newColumnList As New List(Of String)
                newColumnList.Add(cols(colIndex))
                columnLists.Add(newColumnList)
            Next
            data.Add(ID, columnLists)
        End If
    End If
Next

如何读取值：

Dim idList = data.Keys ' List of all ID-Keys '
For Each id As String In idList
    Dim content As List(Of List(Of String)) = data(id)
    Dim field1List As List(Of String) = content(0)     ' AAAAAA,JJJJJJ
    Dim field2List As List(Of String) = content(1)     ' BBBBBB,III
    ' ....
Next

Answer 2

您可以使用StreamReader。并做这样的事情（抱歉它在 C# 中，但你明白了）：

using(StreamReader r = new StreamReader("@C:\somefile.txt"))
{
    while(!r.EndOfStream)
    {
        string line = r.ReadLine();
        string[] data = line.Split(new string[] { "    " }); //use a seperator that is approriate
        //constructor the dictionary yourself
    }
}

编辑：然后对于你的结构，你有一个字典：

IDictionary - 键：id 值：Truple 或创建你自己的元组类，如果你无权访问id 正如@Tim 建议的那样。

如果你可以做一些事情而不是使用通用的，我会建议这样做。

public class Tuple<T,Q,R>
{
    public T First { get; set; }
    public Q Second { get; set; }
    public R Third { get; set; }
}