使 ReadArgs 1.0 使用单个参数

Question

使用 ReadArgs 包，它似乎不支持单参数情况。

{-# LANGUAGE ScopedTypeVariables #-}

import ReadArgs (readArgs)

main = do
  (foo :: Int) <- readArgs
  print foo

错误是（当使用版本 1.0 时）：

No instance for (ReadArgs.ArgumentTuple Int)
  arising from a use of `readArgs'

我的问题有两个：

1. readArgs 是如何工作的？
2. 如何调整该库以使其也可以使用单个参数？

NB ReadArgs 1.1 版本消除了这个“错误”；见评论。

Answer 1

据我所知，该包使用元组来模拟类型安全的异构列表。正如您所注意到的，当您只需要一个参数时，这会导致问题，因为 Haskell 中没有一元组。

但是，该包还为异构列表提供了适当的类型，可以使用它来代替元组： :& 类型。您可以使用类似于 : 运算符的方式使用它，并使用空元组 () 作为终止符：

(foo :: Int) :& (bar :: String) :& () <- readArgs

这对于一个参数来说很简单：

(foo :: Int) :& () <- readArgs

Answer 2

另一个答案，只是为了好玩：具体化 Daniel Wagner 为 OneTuple 添加实例的建议：

{-# LANGUAGE ScopedTypeVariables #-}

import ReadArgs
import Data.Tuple.OneTuple

instance (Argument a) => ArgumentTuple (OneTuple a) where
  parseArgsFrom ss = do
    a :& () <- parseArgsFrom ss
    return $ OneTuple a
  usageFor (OneTuple a) = usageFor (a :& ())

main = do
    OneTuple (foo :: Int) <- readArgs
    print foo

大部分是从 Adam Wagner 的解决方案中窃取的。令人惊讶的是，所有额外的语言编译指示都可以被删除。

这可能听起来很愚蠢，但由于某种原因，OneTuple (foo :: Int) <- readArgs 并不像我想象的那么难看。

Answer 3

我不太明白我需要启用的所有扩展，但是您可以定义一个 ReadArgs.ArgumentTuple a 的实例（即使它实际上不是一个语义上正确的名称），如下所示：

{-# LANGUAGE FlexibleInstances, UndecidableInstances,
             OverlappingInstances, ScopedTypeVariables #-}

import ReadArgs

instance (Argument a) => ArgumentTuple a where
  parseArgsFrom ss = do
    a :& () <- parseArgsFrom ss
    return a
  usageFor a = usageFor (a :& ())

main = do
    (foo :: Int) <- readArgs
    print foo

另外，我我不太确定这个实例是否有任何问题，尽管它适用于您提供的示例。我认为图书馆丢失它是有原因的，但我可能是错的。

更新

在尝试了一些事情之后，为了确保它们仍然有效（如下面的示例），我相当确信这不会导致任何问题，所以也许它（或类似的东西）的存在只是一个疏忽。

main = do
    (foo :: Int, bar :: Int) <- readArgs
    print foo
    print bar

Answer 4

一种迟钝的解决方案是滥用“可选参数”功能：

(foo :: Int, _ :: Maybe ()) <- readArgs

即使您提供 () 作为第二个参数，它也会默默地工作：

$ runhaskell args.hs 3 ()
3

并稍微搞乱使用消息：

$ runhaskell args.hs 3 foo
usage: args.hs Int [()]

但它确实拒绝额外的参数不是 ()，并且它确实按预期工作：

$ runhaskell args.hs 3
3