访问 CoffeeScript 类中的变量

Question

在下面的代码中，我的印象是使用“粗箭头”将允许我访问类变量。相反，无论箭头是粗箭头还是细箭头，我都无法访问“@accounts”变量。

有什么建议吗？

class MyClass
  accounts:[]
  constructor: (@accounts) -> 
    ($ '.the_buttons').live 'click', bind_clicks

  bind_clicks = (event) -> 
    console.log @accounts

jQuery -> 
  m = new MyClass([1, 2, 3])

谢谢。

更新

看起来我之前输入错误导致了一些问题。

下面的代码可以解决这个问题

class MyClass
  accounts:[]
  constructor: (@accounts) -> 
    ($ '.the_buttons').live 'click', (event) => bind_clicks(event)

  bind_clicks: (event) => 
    console.log @accounts

jQuery -> 
  m = new MyClass([1, 2, 3])

，但是，将 bind_clicks 设为公共方法感觉很奇怪。

Answer 1

您可以

class MyClass
  bind_clicks = (event) -> 
    console.log @accounts

  accounts:null
  constructor: (@accounts) -> 
    ($ '.the_buttons').live 'click', bind_clicks


jQuery -> 
  m = new MyClass([1, 2, 3])

在实例方法之前声明bind_clicks。这是私人的。但是，它是一个私有类方法。它会生成一个闭包，这就是原因。我建议使用 _bind_clicks，下划线前缀是定义私有方法的常见约定。因为这在 javascript 中并不存在。

当你声明accounts:[]时也要小心，我建议accounts:null，更多关于这个：http:// html5stars.com/?p=148

Answer 2

另一种可能的方法是这样做。这和你的很相似。

class MyClass
  constructor: (@accounts) -> 
    $('body').live 'click', @bind_clicks

  bind_clicks: (event) => 
    console.log @accounts

$ ->
  m = new MyClass([1, 2, 3])

不要引用我的话，但我不认为 JS 有任何公共/私有方法的概念。我想如果你不想暴露这个方法，你可以这样做。但如果您多次使用此方法，您可能会面临风险或重复操作。

class MyClass
  constructor: (@accounts) -> 
    $('body').live 'click', (event) => 
      console.log @accounts

$ ->
  m = new MyClass([1, 2, 3])

祝你好运！
Sandro

注意：我将事件与主体限制在一起，以便我可以测试代码。

Answer 3

您可以将bind_clicks设置为私有，如下所示：

class MyClass
  accounts:[]
  constructor: (@accounts, @button) ->
    bind_clicks = (event) =>
      console.log @accounts 
    @button.click bind_clicks

class Button
  click: (@f) ->
  do_click: -> @f('event') 

button = new Button()
m = new MyClass([1, 2, 3], button)
console.log m.bind_clicks # undefined (private)
button.do_click() # [1, 2, 3]

Answer 4

您可以尝试一下： http://jsfiddle.net/zp6LJ/1/

私有方法将必须在构造函数中定义才能实现您正在寻找的内容。

class MyClass
  accounts:[]
  constructor: (@accounts) -> 
    bind_clicks = (event) =>
      console.log @accounts

    $('.the_buttons').click bind_clicks

jQuery -> 
  m = new MyClass([1, 2, 3])