如何从 javascript 向 qml 发出信号

Question

我想从 javascript 文件发出信号并在 qml 文件中接收它（以查找耗时的操作何时完成）。

我该怎么做呢？

Answer 1

亚历克斯和拉贾的解决方案都没有真正回答这个问题。 Alex 的方法是直接从 javascript 代码调用 QML slot 方法，而 Raja 的方法是从 Javascript 代码设置 QML 对象的属性值。这两种方法都否定了信号/时隙机制的主要优点，即信令对象不需要知道时隙。

博客文章（不是我的）。它包括在 javascript 文件中创建一个 QML 对象（通过 Qt.createQmlObject() 函数），该对象的唯一功能是包含 javascript 的对象信号。信号是通过调用内部 QML 对象信号（例如 internalQmlObject.signalName()）从 javascript 发出的，并且 javascript 对象信号可以使用通常的 connectjavascriptObject.internalQmlObject.signalName.connect(receiver.slotName) 的 code> 机制。

下面是根据博客文章改编的示例：

javascript_object.js：

var internalQmlObject = Qt.createQmlObject('import QtQuick 2.0; QtObject { signal someSignal(int value) }', Qt.application, 'InternalQmlObject');

function doSomething() {
    internalQmlObject.someSignal(42);
}

test.qml：

import QtQuick 2.0
import 'javascript_object.js' as JavascriptObject

Rectangle {

    Rectangle {
        id: someComponent

        function someSlot(v) {
            console.log("Signal received " + v);
        }
    }

    Component.onCompleted: {
        JavascriptObject.internalQmlObject.someSignal.connect(someComponent.someSlot);
        JavascriptObject.doSomething();
    }
}

执行时会给出以下内容：

% qmlscene test.qml
Signal received 42

Answer 2

谢谢你，@RajaVarma。

我为自己找到了解决方案。

在qml-file中：创建元素Item（我的loginItem），其中包含扮演插槽角色的函数。
例如（我需要知道何时处理登录事件）：

import "scripts/auth.js" as Auth
...
Item {
   id: loginItem

   // Send himself to javascript module named Auth
   Component.onCompleted: {
      Auth.setLoginItem(loginItem);
   }

   // "Slot" function
   function logged() {
      console.debug("Login successfully");
      // Do something
      ...
   }
}

在js文件中：为loginItem创建接收器并使用它。

var loginItem;

function setLoginItem(tempLoginItem) {
    loginItem = tempLoginItem;
}

...
   // Emit "signal"
   loginItem.logged();
...

Answer 3

嗯，从真实的 JS 文件中调用信号是非常 hacky 的。但有一个更好的选择，恕我直言，我自己用过它。创建您自己的类。

MyClass.qml

import QtQuick 2.0

QtObject
{
    property var myVariable
    function myFunction() { console.log("emitting signal"); mySignal() }
    signal mySignal
}

这样就可以轻松实现所需的封装。您甚至可以很好地连接到该对象。

然后你可以用它做任何你想做的事：从中创建一个单例，创建一个全局对象，实例化它。