如何模拟“外连接”在核心逻辑中？

Question

我刚刚开始使用 core.logic，为了解决它，我试图实现一些简单的东西，类似于我目前正在专业处理的问题。然而，问题的一部分让我难住了......

作为我的示例的简化，如果我有一个项目目录，其中一些仅在某些国家/地区可用，而有些则在特定国家/地区不可用。我希望能够指定项目列表和例外情况，例如：

(defrel items Name Color)
(defrel restricted-to Country Name)
(defrel not-allowed-in Country Name)

(facts items [['Purse 'Blue]
              ['Car 'Red]
              ['Banana 'Yellow]])

(facts restricted-to [['US 'Car]])

(facts not-allowed-in [['UK 'Banana]
                       ['France 'Purse]])

如果可能，我宁愿不指定所有国家/地区的允许入境，因为受限制的项目集相对较小，并且我'我希望能够进行一次更改以允许/排除给定国家/地区的某个项目。

如何编写一个规则来给出一个国家/地区的项目/颜色列表，并具有以下约束：

• 该项目必须位于项目列表中
• 国家/项目不得位于“不允许进入”列表中
• 任何一个：
  • 该商品的限制列表中没有国家/地区
  • 该国家/地区/商品对位于限制列表中

有某种方法可以做到这一点吗？我是否以完全错误的方式思考事情？

Answer 1

通常当你开始否定逻辑编程的目标时，你需要达到非关系操作（Prolog 中的 cut，core.logic 中的 conda）。

该解决方案只能使用基本参数来调用。

(defn get-items-colors-for-country [country]
  (run* [q]
    (fresh [item-name item-color not-country]
      (== q [item-name item-color])
      (items item-name item-color)
      (!= country not-country)

      (conda
        [(restricted-to country item-name)
         (conda
           [(not-allowed-in country item-name)
            fail]
           [succeed])]
        [(restricted-to not-country item-name)
         fail]
        ;; No entry in restricted-to for item-name
        [(not-allowed-in country item-name)
         fail]
        [succeed]))))

(get-items-colors-for-country 'US)
;=> ([Purse Blue] [Banana Yellow] [Car Red])

(get-items-colors-for-country 'UK)
;=> ([Purse Blue])

(get-items-colors-for-country 'France)
;=> ([Banana Yellow])

(get-items-colors-for-country 'Australia)
;=> ([Purse Blue] [Banana Yellow])

完整解决方案

Answer 2

Conda 可能会使代码复杂化，使用 nafc，如果需要，您可以更轻松地重新排序目标。
这仍然是非关系性的！ :)

(ns somenamespace
  (:refer-clojure :exclude [==])
  (:use [clojure.core.logic][clojure.core.logic.pldb]))

(db-rel items Name Color)
(db-rel restricted-to Country Name)
(db-rel not-allowed-in Country Name)

(def stackoverflow-db 
  (db [items 'Purse 'Blue]
      [items  'Car 'Red]
      [items 'Banana 'Yellow]
      [restricted-to 'US 'Car]
      [not-allowed-in 'UK 'Banana]
      [not-allowed-in 'France 'Purse]))


(defn get-items-colors-for-country [country]
  (with-db stackoverflow-db
    (run* [it co]
         (items  it co)
         (nafc not-allowed-in country it)
         (conde 
          [(restricted-to country it)]
          [(nafc #(fresh [not-c] (restricted-to not-c %)) it)]))))

(get-items-colors-for-country 'US)
;=> ([Purse Blue] [Banana Yellow] [Car Red])

(get-items-colors-for-country 'UK)
;=> ([Purse Blue])

(get-items-colors-for-country 'France)
;=> ([Banana Yellow])

(get-items-colors-for-country 'Australia)
;=> ([Purse Blue] [Banana Yellow])

有关更多示例： https://gist.github.com/ahoy-jon/cd0f025276234de464d5