Delphi XE 和使用 OnKeyDown 捕获箭头键

Question

我希望我的表单能够处理箭头键，而且我可以做到——只要表单上没有按钮。这是为什么呢？

Answer 1

关键消息由接收这些消息的控件本身进行处理，这就是为什么当您使用按钮时表单不会接收消息。因此，通常您必须对这些控件进行子类化，但 VCL 足够友善地询问父子表单如果感兴趣，该怎么办：

type
  TForm1 = class(TForm)
    ..
  private
    procedure DialogKey(var Msg: TWMKey); message CM_DIALOGKEY;
    ..


procedure TForm1.DialogKey(var Msg: TWMKey); 
begin
  if not (Msg.CharCode in [VK_DOWN, VK_UP, VK_RIGHT, VK_LEFT]) then
    inherited;
end;

François 编辑： 要回答 OP 原始问题，您需要以某种方式调用 onKeyDown 以便他的事件代码可以工作（随意编辑；评论太长）。

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    procedure FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
  private
    { Private declarations }
    procedure DialogKey(var Msg: TWMKey); message CM_DIALOGKEY;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.DialogKey(var Msg: TWMKey);
begin
  case Msg.CharCode of
    VK_DOWN, VK_UP, VK_RIGHT, VK_LEFT:
      if Assigned(onKeyDown) then
        onKeyDown(Self, Msg.CharCode, KeyDataToShiftState(Msg.KeyData));
    else
      inherited
  end;
end;

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  case Key of
    VK_DOWN: Top := Top + 5;
    VK_UP: Top := Top - 5;
    VK_LEFT: Left := Left - 5;
    VK_RIGHT: Left := Left + 5;
  end;
end;

Answer 2

箭头键用于在表单上的按钮之间导航。这是标准的 Windows 行为。尽管您可以禁用此标准行为，但在违反平台标准之前您应该三思而后行。箭头键用于导航。

如果您想全面了解按键如何通过消息循环，我建议您阅读 一把钥匙的奥德赛。如果您想在按键变成导航键之前拦截该按键，则需要在 IsKeyMsg 或更早版本中执行此操作。例如，Sertac 的答案就给出了这样一种可能性。

Answer 3

只有具有焦点的对象才能接收键盘事件。

要让表单能够访问箭头键事件，
在表单的公共部分声明一个 MsgHandler。
在表单创建构造函数中，将 Application.OnMessage 分配给此 MsgHandler。

下面的代码仅在箭头键来自 TButton 后代时拦截它们。可以根据需要添加更多控件。

procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.OnMessage := Self.MsgHandler;
end;

procedure TForm1.MsgHandler(var Msg: TMsg; var Handled: Boolean);
var
  ActiveControl: TWinControl;
  key : word;
begin
  if (Msg.message = WM_KEYDOWN) then
    begin
      ActiveControl := Screen.ActiveControl;
      // if the active control inherits from TButton, intercept the key.
      // add other controls as fit your needs 
      if not ActiveControl.InheritsFrom(TButton)
        then Exit;

      key := Msg.wParam;
      Handled := true;
      case Key of // intercept the wanted keys
        VK_DOWN : ; // doStuff
        VK_UP : ; // doStuff
        VK_LEFT : ; // doStuff
        VK_RIGHT : ; // doStuff
        else Handled := false;
      end;
   end;
end;

Answer 4

因为它们会抢先处理将焦点设置到下一个可用的 WinControl 上的问题。
（我很确定，如果您放置“编辑”而不是“按钮”，您会看到相同的结果）。

如果您想自己处理它们，您可以为应用程序提供一个 OnMessage 事件，该事件将在处理它们之前对其进行过滤并在那里自行处理。

Answer 5

var
KBHook: HHook; {this intercepts keyboard input}

implementation

{$R *.dfm}

function KeyboardHookProc(Code: Integer; WordParam: Word; LongParam: LongInt): LongInt; stdcall;
 begin
 case WordParam of
   vk_Space: ShowMessage ('space')  ;
   vk_Right:ShowMessage ('rgt') ;
   vk_Left:ShowMessage ('lft') ;
   vk_Up: ShowMessage ('up') ;
   vk_Down: ShowMessage ('down') ;
  end; {case}
 end;

procedure TForm4.FormCreate(Sender: TObject);
begin
KBHook:=SetWindowsHookEx(WH_KEYBOARD,@KeyboardHookProc,HInstance,GetCurrentThreadId());
end;

即使控件获得焦点（按钮、列表框），此代码也将起作用，因此请小心某些控件可能会丢失其键盘事件（请阅读 David haffernans 的回答）。

带有聚焦控件的键盘事件

例如：如果您的应用程序中有文本框并且还想接收文本（如果聚焦），则

添加一个 applicationevent1

procedure TForm4.ApplicationEvents1Message(var Msg: tagMSG;var Handled: Boolean);
begin
if Msg.message = WM_KEYFIRST then
  KBHook:=SetWindowsHookEx(WH_KEYBOARD,@KeyboardHookProc,HInstance,GetCurrentThreadId());
end;

在 函数的底部添加以下代码KeyboardHookProc

UnhookWindowsHookEx(KBHook);

删除。

KBHook:=SetWindowsHookEx(WH_KEYBOARD,@KeyboardHookProc, HInstance, 
GetCurrentThreadId());

并从 oncreate 事件中