D opBinary()() 重载错误？

Question

当我尝试在简单的 Vector 结构上重载 opBinary 时，我收到一个奇怪且无意义的错误：

struct Vector(T)
{
    T x, y;

    Vector opBinary(string op)(Vector!float vector)
    {
        return Vector (
            mixin("x" ~ op ~ "vector.x"),
            mixin("y" ~ op ~ "vector.y")
        );
    }

    Vector opBinary(string op)(Vector!double vector)
    {
        return Vector (
            mixin("x" ~ op ~ "vector.x"),
            mixin("y" ~ op ~ "vector.y")
        );
    }
}

void main()
{
    auto dVec = Vector!double();
    auto fVec = Vector!float();

    auto aVec = dVec + fVec; // Adding this line causes error (see below)
}

我收到的错误很简单：“opBinary(string op)”。没有行号，什么都没有。这显然并没有给我很多继续下去的机会。还有其他方法可以处理这种情况吗？这是一个已知的错误吗？

我在 Windows 7 上使用 DMD 2.057。尚未在 Linux 上进行测试。

[编辑]对代码进行了一些清理以提高可读性。

Answer 1

完整的错误是：

main.d(27): Error: template main.Vector!(double).Vector.opBinary(string op) opBinary(string op) matches more than one template declaration, main.d(5):opBinary(string op) and main.d(13):opBinary(string op)

VisualD 无法解析它，导致您看到的错误。你用的是VisualD吗？

如果将代码更改为类似以下内容，则该代码可以工作：

struct Vector(T)
{
    T x, y;

    Vector opBinary(string op, U)(Vector!U vector) if(is(typeof(mixin("x" ~ op ~ "vector.x")) : T))
    {
        return Vector(
            mixin("x" ~ op ~ "vector.x"),
            mixin("y" ~ op ~ "vector.y")
        );
    }
}