所有恰好有 n 位的二进制数

Question

我需要一个谓词来生成列表中长度为 N 的所有二进制数。

使用示例：

?- bins(2,L).
L = [[0,0], [0,1], [1,0], [1,1]].    % expected result

Answer 1

无需使用 findall/3！

我们基于 clpfd 定义 bins/2 ，foldl/4, Prolog lambda、if_/3、和(#<)/3。

:- use_module(library(lambda)).
:- use_module(library(clpfd)).

bins(N,Zss) :-
   if_(N #< 1,
       ( N #= 0, Zss = [[]] ),
       ( N #= N0+1,
         bins(N0,Xss),
         foldl(\Bs^phrase(([[0|Bs]],[[1|Bs]])),Xss,Zss,[]))).

使用示例：

?- bins(4,Zss).
Zss = [[0,0,0,0],[1,0,0,0],[0,1,0,0],[1,1,0,0],
       [0,0,1,0],[1,0,1,0],[0,1,1,0],[1,1,1,0],
       [0,0,0,1],[1,0,0,1],[0,1,0,1],[1,1,0,1],
       [0,0,1,1],[1,0,1,1],[0,1,1,1],[1,1,1,1]].

这是最常见的查询：

?- bins(N,Zss).
  N = 0, Zss = [[]]
; N = 1, Zss = [[0],[1]]
; N = 2, Zss = [[0,0],[1,0],[0,1],[1,1]]
; N = 3, Zss = [[0,0,0],[1,0,0],[0,1,0],[1,1,0],[0,0,1],[1,0,1],[0,1,1],[1,1,1]]
...

Answer 2

可能有更好的方法，但这是使用 findall 的解决方案

bins(N,L) :-
    findall(Num,binary_number(N,Num),L).

binary_number(0,[]).
binary_number(N,[D|Ds]) :-
    N > 0,
    member(D,[0,1]),
    N1 is N - 1,
    binary_number(N1,Ds).

Answer 3

或者：

member_(A, B) :- member(B, A).
bins(Size, Result) :-
    findall(L, (length(L, Size), maplist(member_([0, 1]), L)), Result).

可以使用 lambda 进行简化模块 ：

bins(Size, Result) :-
    findall(L, (length(L, Size), maplist(\X^member(X, [0, 1]), L)), Result).