使用余弦定理计算角度，给定 2 点并计算 1 点

Question

我正在 AIR (as3) 中开发一款移动游戏。我为这个游戏创建了一些机器人，它们最初只是四处游荡。但当奖金登场时，他们就必须走向奖金。

新奖励的检测和机器人的移动工作正常，但当新奖励进入阶段时，操作会出现问题。

基本上，这就是它的工作原理（或者我尝试让它工作）：

我的机器人随着他的旋转作为参数移动。 （工作正常）

private function moveToNextLocation():void
{
    var angle:Number = _rotation * 0.0174532925; // 1 degree = 0.0174532925 radians
    var speedX:Number = Math.sin(angle) * _speed; 
    var speedY:Number = -Math.cos(angle) * _speed;

    if (_turnLeft && !_moveToBonus){
        _rotation -= _rotationStep * (_speed / _maxSpeed);
    }
    else if (_turnRight && !_moveToBonus){
        _rotation += _rotationStep * (_speed / _maxSpeed);
    }

    this.x += speedX; this.y += speedY;
}

所以，为了知道是否出现新的奖金，我首先捕获一个事件：

protected function onNewBonusAppeared(event:BonusEvent):void
{
    trace("new bonus appeared!");
    _moveToBonus = true;
    _rotation = getRotation(new Point(event.bonus.x, event.bonus.y));
    trace("Heading to " + event.bonus.type + " with new rotation: "  + _rotation);
}

我的机器人现在位于 A 点，通常会前往 B 点（正常的下一个位置）。 然后，新的奖励出现在 C 点（下一个位置）。 我想用余弦定理来解决这个问题，因为我需要 A 的角度来知道我的机器人的新旋转。 这就是我尝试计算的方法：

// calculate new rotation 
private function getRotation(nextLocation:Point):Number
{
    //sources:
    //http://www.teacherschoice.com.au/maths_library/trigonometry/triangle_given_3_points.htm
    //http://en.wikipedia.org/wiki/Law_of_cosines
    //http://stackoverflow.com/questions/1211212/how-to-calculate-an-angle-from-three-points

    //Calculate current angle and corners
    var angle:Number = _rotation * 0.0174532925;
    var currentLocation:Point = new Point(this.x, this.y);
    var normalNextLocation:Point = new Point(Math.sin(angle) * _speed, -Math.cos(angle) * _speed);

    //Calculate lengths of the 3 sides of the triangle  
    var lengthA:Number = calculateLength(normalNextLocation, nextLocation);
    var lengthB:Number = calculateLength(currentLocation, nextLocation);
    var lengthC:Number = calculateLength(currentLocation, normalNextLocation);

    //Calculate the difference in rotation  
    //-------------THIS IS WHERE IT GOES WRONG-----------
    var deltaRotation:Number = calculateAndInverseCosineRule(lengthA, lengthB, lengthC);

    //positive or negative rotation difference
    if (normalNextLocation.y < nextLocation.y)
        return _rotation - deltaRotation;
    else
        return _rotation + deltaRotation;
}
private function calculateLength(a:Point, b:Point):Number
{
    //SQRT((x2 - x1)² + (y2 - y1)²)
    return Math.sqrt(Math.pow(b.x - a.x, 2) + Math.pow(b.y - a.y, 2));
}
private function calculateAndInverseCosineRule(lengthA:Number, lengthB:Number, lengthC:Number):Number
{
    //a² = b² + c² - 2*b*c*cos(alpha)
    //cos(alpha) = (b² + c ² - a²) / (2 * b * c)
    //alpha = cos^-1(cos(alpha))
    var cos:Number = (Math.pow(lengthB, 2) + Math.pow(lengthC, 2) - Math.pow(lengthA, 2))
                         / (2 * lengthB * lengthC);
    trace("cos: ", cos); //returns NAN at some point... don't know why
    return Math.acos(cos);
}

我已经在这个问题上搜索了很长一段时间，但找不到答案......有人看到我做错了什么吗？ - [固定的]

Answer 1

这里有一个拼写错误：

var cos:Number = (Math.pow(lengthB, 2) + Math.pow(lengthC, 2) - Math.pow(lengthC, 2))

要减去的数量应该是 Math.pow(lengthA, 2)。按照原样，您可以计算（模浮点误差）lengthB^2/(2*lengthB*lengthC)。如果 lengthB == 0，这会产生一个 NaN，我怀疑这就是发生的情况。这意味着 nextLocation 与 currentLocation 相同或至少非常接近。

另一方面，normalNextLocation 不应该是 currentLocation + timeStep*velocity 吗？据我所知，您将其设置为velocity。