在设置为 nil 的对象引用上调用 Free 不应该在每次调用时都会抛出访问冲突吗？

Question

我从单元 DBXCommon.pas （在 Delphi XE 中）收到访问冲突。当我查看代码时，我看到如下内容（在感叹号处）：

function TDBXConnectionFactory.GetConnection(const DBXContext: TDBXContext;
  const ConnectionProperties: TDBXProperties): TDBXConnection;
var
  ConnectionBuilder:  TDBXConnectionBuilder;
  DelegatePath:       TDBXDelegateItem;
  Connection:         TDBXConnection;
  CombinedProperties: TDBXProperties;
begin
  //...
  ConnectionBuilder := TDBXConnectionBuilder.Create;
  Connection        := nil;
  try
    //..lots of setting ConnectionBuilder properties
    ConnectionBuilder.FInputPassword := CombinedProperties[TDBXPropertyNames.Password];
    Connection := ConnectionBuilder.CreateConnection;
    Connection.Open;
    Result     := Connection;
!!  Connection := nil;
  finally
!!  Connection.Free;
    ConnectionBuilder.Free;
  end;
end;

但我在 DBXCommon.pas 中看到更多类似这样的构造（首先分配 Nil，然后分配 Free）。这是我不知道的一些构造，还是这真的导致每次调用这段代码时发生访问冲突？

Answer 1

对空引用调用 Free 始终是安全的。查看 TObject.Free 的实现来了解原因。

此代码是工厂函数的示例。它的工作是创建一个类的新实例，但如果失败，它需要确保在抛出异常时不会泄漏半创建的实例，因此它调用Free。当确定它会成功时，它将结果的所有权转移给调用者。它仍然调用 Free，但如果它已经转移了所有权，那么它最终会在空引用上调用 Free，并且不会造成任何损害。这段代码就是转移所有权的：

Result := Connection;
Connection := nil;

我编写工厂函数的方式将消除单独的Connection变量。我会直接在 Result 中构造结果，但如果出现异常则释放它，如下所示：

function TDBXConnectionFactory.GetConnection(const DBXContext: TDBXContext;
  const ConnectionProperties: TDBXProperties): TDBXConnection;
var
  ConnectionBuilder:  TDBXConnectionBuilder;
  DelegatePath:       TDBXDelegateItem;
  Connection:         TDBXConnection;
  CombinedProperties: TDBXProperties;
begin
  //...
  ConnectionBuilder := TDBXConnectionBuilder.Create;
  try
    //..lots of setting ConnectionBuilder properties
    ConnectionBuilder.FInputPassword := CombinedProperties[TDBXPropertyNames.Password];
    Result := ConnectionBuilder.CreateConnection;
    try
      Result.Open;
    except
      Result.Free;
      raise;
    end;
  finally
    ConnectionBuilder.Free;
  end;
end;

这具有相同的效果。

Answer 2

在 nil 引用上调用 Free 是安全的，因为它会检查 Self <> 的实现。 nil 在调用 Destroy 之前。请参阅Embarcadero 论坛中 Allen Bauer 的解释 引入了 TObject.Free。我在这里只引用相关的引用：

在 TObject 上引入非虚拟 Free 方法的唯一原因是在析构函数中用作以下内容的简单简写：

if FField <> nil then
  FField.Destroy;

Answer 3

TObject.Free 基本上实现为 if Self <> nil 然后 Destroy，因此上面的代码不应引发任何异常。