对 Mathematica 列表中每个元素的第二个组件进行运算

Question

我可以使用以下方法对列表中每个元素的第一个组件进行一些操作（在本例中为 ToString）：

{ToString@#[[1]], Rest@#}~Flatten~1 & /@ {{1, 2}, {3, 4, 5}}

但是，我有几个问题：

• 它不适用于 {ToString@#[[1]], Rest@#}~压平~1 & /@{{1, 2}, 2, {3, 4, 5}} 原因显而易见。如何让它也能工作 这个案子？预期输出为 {{"1", 2}, 2, {"3", 4, 5}}。
• 如何轻松对第二个（或第三个等）组件执行此操作？即我希望输出为 {{0}, {1, "2"}, {3, "4", 5}, {6, "7", 9, 10}}
• 是有一种方法可以使用模式/规则（比如 /.{#[[1]]->ToString[#[[1]]]}) 对于这种操作？所以请列出您可能想到的所有解决方案，无论效率如何。

多谢！

Answer 1

直到我编写了它之后，我才意识到这与 Leonid 的核心功能相同。也许这仍然表明这可能比他相当复杂的职能更透明一些。

lst = {{1, 2}, 2, {3, 4, 5}};

Replace[lst, {a_, b__} :> {ToString@a, b}, 1]

{{"1", 2}, 2, {"3", 4, 5}}

然后可以使用 {x:Repeated[_, {4}], a_, b__} :> {x, ToString@a, b}, 1] 用于第五个索引，依此类推。

Answer 2

下面的函数基本上应该做你想做的事：

ClearAll[applyToAll];
applyToAll[f_, list_List, n_Integer] :=
   applyToAll[x_ :> f[x], list, n];
applyToAll[rule : (_Rule | _RuleDelayed), list_List, n_Integer] :=
  Replace[
      list, {left : Repeated[_, {n - 1}], el_, rest___} :> 
        {left, el /. rule, rest}, {1}];

并且可以接受规则。例如：

In[192]:= 
applyToAll[ToString, {{1,2},2,{3,4,5}},1]//InputForm
Out[192]//InputForm=  {{"1", 2}, 2, {"3", 4, 5}}

In[193]:= applyToAll[ToString,{{0},{1,2},{3,4,5},{6,7,9,10}},2]//InputForm
Out[193]//InputForm=  {{0}, {1, "2"}, {3, "4", 5}, {6, "7", 9, 10}}

In[194]:= applyToAll[x_?OddQ:>ToString[x],{{0},{1,2},{3,4,5},{6,7,9,10}},2]//InputForm
Out[194]//InputForm= {{0}, {1, 2}, {3, 4, 5}, {6, "7", 9, 10}}

Answer 3

另一种方便的方法可能是将 ReplacePart 与 RuleDelayed 一起使用，

例如，将每个子列表的第 3 部分（如果存在）转换为字符串：

ReplacePart[#, 3 :>  ToString@#[[3]]] & /@ {{1, 2}, 
   2, {3, 4, 5}, {6, 7, 9, 10}} // InputForm

给出输出：

{{1, 2}, 2, {3, 4, "5"}, {6, 7, "9", 10}}

类似地，要将每个子列表的第 1 部分转换为字符串：

ReplacePart[#, 1 :>  ToString@#[[1]]] & /@ {{1, 2}, 
   2, {3, 4, 5}} // InputForm

给出：

{{"1", 2}, 2, {"3", 4, 5}}

Answer 4

从长远来看，我认为这可能是一种更简单的方法，即使它并不完全符合您的要求：

rep[f_, pos_][x_List] := MapAt[f, x, pos]
rep[__][x_] := x

lst = {{1, 2}, 2, {3, 4, 5}};

rep[ToString, 2] /@ lst

{{1, "2"}, 2, {3, "4", 5}}

您可以根据需要向 rep 的定义添加任意模式和条件。