在 Mathematica 中使用 MapAt 中的 All

Question

我经常有一个成对的列表，因为

data = {{0,0.0},{1,12.4},{2,14.6},{3,25.1}}

我想对所有第二个元素做一些事情，例如Rescale，而不接触第一个元素。我知道的最巧妙的方法是：

Transpose[MapAt[Rescale, Transpose[data], 2]]

一定有一种方法可以做到这一点，而无需那么多的Transposeing。我希望这样的东西能够工作：

MapAt[Rescale, data, {All, 2}]

但我的理解是 MapAt 采用 Position 样式规范而不是 Part 样式规范。正确的解决办法是什么？

为了澄清，

我正在寻找一个不必重复自己的解决方案，因此缺少双 Transpose 或双 [[All,2]]，因为我认为重复一个信号，我没有以最简单的方式做某事。然而，如果消除重复需要引入中间变量或命名函数或其他额外的复杂性，则转置/非转置解决方案可能已经是正确的。

Answer 1

使用 Part：

data = {{0, 0.0}, {1, 12.4}, {2, 14.6}, {3, 25.1}}

data[[All, 2]] = Rescale @ data[[All, 2]];

data

如果需要，请先创建一个副本到。 （data2 = data 然后 data2[[All, 2]] 等）

---

修改我的答案以跟上 ruebenko 的步伐，这也可以做成一个函数：

partReplace[dat_, func_, spec__] :=
  Module[{a = dat},
    a[[spec]] = func @ a[[spec]];
    a
  ]

partReplace[data, Rescale, All, 2]

这是设计很一般。

Answer 2

我参加聚会迟到了，我所描述的内容与@先生的内容几乎没有什么不同。巫师有，所以最好将此答案视为对其解决方案的补充。我的部分借口是，首先，下面的函数封装的东西有点不同，更接近 MapAt 本身的语法，其次，它更通用，并且可以选择与 Listable 一起使用 函数，第三，我正在重现过去的解决方案 Mathgroup 线程正是针对这个问题，该问题已有 2 年多了，所以我不是抄袭:)

所以，这是函数：

ClearAll[mapAt,MappedListable]; 
Protect[MappedListable]; 
Options[mapAt] = {MappedListable -> False}; 
mapAt[f_, expr_, {pseq : (All | _Integer) ..}, OptionsPattern[]] := 
  Module[{copy = expr}, 
    copy[[pseq]] = 
      If[TrueQ[OptionValue[MappedListable]] && Head[expr] === List, 
        f[copy[[pseq]]], 
        f /@ copy[[pseq]] 
      ]; 
    copy]; 
mapAt[f_, expr_, poslist_List] := MapAt[f, expr, poslist]; 

这与@Mr. 的想法相同。使用向导，但存在以下差异： 1. 如果规范不符合规定形式，将自动使用常规 MapAt 2. 并非所有函数都是Listable。 @Mr.Wizard 的解决方案假设函数是 Listable 或者我们想要将其应用于整个列表。在上面的代码中，您可以通过 MappedListable 选项指定这一点。

我还将借用我在上述线程中的回答中的一些示例：

In[18]:= mat=ConstantArray[1,{5,3}];

In[19]:= mapAt[#/10&,mat,{All,3}]
Out[19]= {{1,1,1/10},{1,1,1/10},{1,1,1/10},{1,1,1/10},{1,1,1/10}}

In[20]:= mapAt[#/10&,mat,{3,All}]
Out[20]= {{1,1,1},{1,1,1},{1/10,1/10,1/10},{1,1,1},{1,1,1}}

在大型列表上进行测试表明，使用可列表性可以提高性能，尽管这里不是那么显着：

In[28]:= largemat=ConstantArray[1,{150000,15}];

In[29]:= mapAt[#/10&,largemat,{All,3}];//Timing
Out[29]= {0.203,Null}

In[30]:= mapAt[#/10&,largemat,{All,3},MappedListable->True];//Timing
Out[30]= {0.094,Null}

这可能是因为对于上述函数 (#/10& ;），Map（在 mapAt 内部用于 MappedListable->False （默认）设置，能够在下面的例子中，区别更为实质性：

ClearAll[f];
f[x_] := 2 x - 1;

In[54]:= mapAt[f,largemat,{All,3}];//Timing
Out[54]= {0.219,Null}

In[55]:= mapAt[f,largemat,{All,3},MappedListable->True];//Timing
Out[55]= {0.031,Null}

要点是，虽然 f 没有声明为 Listable，但我们知道它的主体由Listable函数构建，因此它可以应用于整个列表 - 但OTOH它不能由Map自动编译，请注意添加。 f 的 Listable 属性将完全被这里错误，会破坏目的，导致 mapAt 在这两种情况下都很慢。

Answer 3

哪个

Transpose[{#[[All, 1]], Rescale[#[[All, 2]]]} &@data]

会返回您想要的内容（即，它不会更改数据）？

如果不允许Transpose，则

Thread[Join[{#[[All, 1]], Rescale[#[[All, 2]]]} &@data]]

可以工作。

编辑：由于“最短”现在是目标，到目前为止我最好的是：

data\[LeftDoubleBracket]All, 2\[RightDoubleBracket] = Rescale[data[[All, 2]]]

80个字符，这与Mr.Wizard的相同......所以投票给他的回答。

Answer 4

这是另一种方法：

op[data_List, fun_] := 
 Join[data[[All, {1}]], fun[data[[All, {2}]]], 2]

op[data, Rescale]

编辑 1：

Mr.Wizard 的扩展，不会复制其数据。

SetAttributes[partReplace, HoldFirst]
partReplace[dat_, func_, spec__] := dat[[spec]] = func[dat[[spec]]];

像这样使用

partReplace[data, Rescale, All, 2]

编辑2：
或者像这样

ReplacePart[data, {All, 2} -> Rescale[data[[All, 2]]]]

Answer 5

这对我和一个朋友有用

In[128]:= m = {{x, sss, x}, {y, sss, y}}
Out[128]= {{2, sss, 2}, {y, sss, y}}

In[129]:= function[ins1_] := ToUpperCase[ins1];
fatmap[ins2_] := MapAt[function, ins2, 2];

In[131]:= Map[fatmap, m]
Out[131]= {{2, ToUpperCase[sss], 2}, {y, ToUpperCase[sss], y}}