根据 Mahtematica 中内部列表元素的字母顺序对列表列表进行排序

Question

我有一个列表列表，其中的内部列表可能具有可变长度。我需要根据内部列表元素的字母顺序对外部列表进行排序。例如，给定

{{0, 0, 7}, {5, 0, 2, 3}, {0, 0, 10, 0}, {0, 6, 2}, {5, 1, 2}, {0, 3, 6, 1, 4}}

我希望 Sort 之后的输出为

{{0, 0, 10, 0}, {0, 0, 7}, {0, 3, 6, 1, 4}, {0, 6, 2}, {5, 0, 2, 3}, {5, 1, 2}}< /code>

我只是不知道如何处理内部列表的可变长度以便编写比较函数。请帮忙。

编辑

顺便说一句，原始列表是一个数字列表。

编辑 2

例如，我有一个列表：

{{0, 0, 7}, {5, 0, 2, 3}, {0, 0, 11, 0}, {0, 0, 1, 12}, {0, 6, 2}, {5, 1, 2}, {0, 3, 6, 1, 4}}

输出应为：

{{0, 0, 1, 12}, {0, 0, 11, 0}, {0, 0, 7}, {0, 3, 6, 1, 4}, {0, 6, 2 }, {5, 0, 2, 3}, {5, 1, 2}}

原因是1在词法上小于11，即小于比7。

Answer 1

您可以像这样设置词典编排比较器：

lexComp[_, {}] := False;
lexComp[{}, _] := True;
lexComp[{a_, as___}, {b_, bs___}] := a < b || a == b && lexComp[{as}, {bs}];

然后您可以使用它进行排序以获得所需的效果：

Sort[{{0, 0, 7}, {5, 0, 2, 3}, {0, 0, 10, 0}, {0, 6, 2}, {5, 1, 2}, {0, 3, 6, 1, 4}}, lexComp]

{{0, 0, 7}, {0, 0, 10, 0}, {0, 3, 6, 1, 4}, {0, 6, 2}, {5, 0, 2, 3}, {5, 1, 2}}

如果您希望在排序时将数字视为字符串，您可以像这样修改它：

lessAsString[a_, b_] := Order @@ (ToString /@ {a, b}) === 1;

olexComp[_, {}] := False;
olexComp[{}, _] := True;
olexComp[{a_, as___}, {b_, bs___}] := lessAsString[a, b] || a === b && olexComp[{as}, {bs}];

下面是这种排序的示例：

In[5]:= Sort[{{0, 0, 7}, {5, 0, 2, 3}, {0, 0, 11, 0}, {0, 0, 1, 12}, {0, 6, 2}, {5, 1, 2}, {0, 3, 6, 1, 4}}, olexComp]

Out[5]= {{0, 0, 1, 12}, {0, 0, 11, 0}, {0, 0, 7}, {0, 3, 6, 1, 4}, {0, 6, 2}, {5, 0, 2, 3}, {5, 1, 2}}

Answer 2

alphaSort = #[[ Ordering @ Map[ToString, PadRight@#, {2}] ]] &;

这是通过为默认的 Ordering 排序准备数据，然后使用该顺序对原始列表进行排序来实现的。

在这种情况下，将所有列表填充到相同的长度可以防止此 Sort 属性受到干扰：

排序通常通过将较短的表达式放在前面，然后以深度优先的方式比较各个部分来对表达式进行排序。

ToString 用于获取字母顺序而不是数字顺序。

Answer 3

这应该可以做到

{{0, 0, 7}, {5, 0, 2, 3}, {0, 0, 10, 0}, {0, 6, 2}, {5, 1, 2}, {0, 3, 
   6, 1, 4}} // SortBy[#, ToString] &

这一点之所以有效，是因为从词法上来说，逗号和空格位于数字之前，因此 {a,b} 在词法上位于 {a,b,c} 之前。