简单的功率计数

Question

如何在如下表达式中添加 x 的幂数？

x^2f[x]g[x^3]

or

x^2g[x^4]

or

x^2g[x^2f[x^2]]

计数使得所有这些示例都必须返回 6。 我正在考虑将 Count 与某种模式一起使用，但我没有设法为此构建一个模式。

Answer 1

这是我的快速技巧 - 某些行为（请参阅最后一个示例）可能不完全是您想要的：

SetAttributes[countPowers, Listable]
countPowers[expr_, symb_] := Module[{a}, 
  Cases[{expr} /. symb -> symb^a // PowerExpand, symb^n_ :> n, 
        Infinity] /. a -> 1 // Total]

然后

In[3]:= countPowers[{x^2 f[x] g[x^3], x^2 g[x^4], x^2 g[x^2 f[x^2]]}, x]

Out[3]= {6, 6, 6}

和

In[4]:= countPowers[{x^(2 I)  g[x^3], g[x, x^4], 
                       x^2 g[E^(2 Pi I x) , f[x]^x]}, x]

Out[4]= {3 + 2 I, 5, 5}

Answer 2

由于您想将 x 算作 1 的隐式幂，因此可以使用以下形式：

powerCount[x_Symbol][expr_] := 
  Tr @ Reap[PowerExpand[expr] /. {x^n_ :> Sow[n], x :> Sow[1]}][[2,1]]

powerCount[x] /@
  {
   x^2f[x]g[x^3],
   x^2g[x^4],
   x^2g[x^2f[x^2]]
  }

{6, 6, 6}

---

或者，如果这样更易于阅读，也可以不使用 Sow 和 Reap 来编写：

powerCount[x_Symbol][expr_] := 
  Module[{t = 0}, PowerExpand[expr] /. {x^n_ :> (t += n), x :> t++}; t]

---

任一形式都可以变得更简洁使用消失的模式，但可能会牺牲清晰度：

powerCount[x_Symbol][expr_] := 
  Tr @ Reap[PowerExpand[expr] /. x^n_ | x :> Sow[1 n]][[2, 1]]