使用 f2py 编译 Fortran 模块

Question

我有一个 Fortran 模块，我正在尝试使用 f2py 进行编译（如下所列）。当我删除模块声明并将子例程单独保留在文件中时，一切正常。但是，如果模块声明如下所示，我会得到以下结果：

> f2py.py -c -m its --compiler=mingw itimes-s2.f
...
Reading fortran codes...
    Reading file 'itimes-s2.f' (format:fix,strict)
crackline: groupcounter=1 groupname={0: '', 1: 'module', 2: 'interface', 3: 'subroutine'}
crackline: Mismatch of blocks encountered. Trying to fix it by assuming "end" statement.
...
c:\users\astay13\appdata\local\temp\tmpgh5ag8\Release\users\astay13\appdata\local\temp\tmpgh5ag8\src.win32-3.2\itsmodule.o:itsmodule.c:(.data+0xec): undefined reference to `itimes_'
collect2: ld returned 1 exit status

在 f2py 中编译模块或子例程有什么不同？我是否在模块中遗漏了一些导致 f2py 出现问题的重要内容？请注意，当我单独使用 gfortran 时，该模块可以正常编译。

软件：Windows 7； gcc、gfortran 4.6.1 (MinGW)；蟒蛇3.2.2； f2py v2

itimes-s2.f：

  module its

  contains

  subroutine itimes(infile,outfile)

    implicit none

    ! Constants
    integer, parameter :: dp = selected_real_kind(15)

    ! Subroutine Inputs
    character(*), intent(in) :: infile
    character(*), intent(in) :: outfile

    ! Internal variables
    real(dp) :: num
    integer :: inu
    integer :: outu
    integer :: ios

    inu = 11
    outu = 22

    open(inu,file=infile,action='read')
    open(outu,file=outfile,action='write',access='append')

    do
      read(inu,*,IOSTAT=ios) num
      if (ios < 0) exit

      write(outu,*) num**2
    end do

  end subroutine itimes

  end module its

Answer 1

您正在尝试在 Python 模块中包含 Fortran 模块。如果你想要这样，名称必须不同，例如

 f2py.py -c -m SOMEDIFFERENTNAME itimes-s2.f

结果将被称为pythonmodule.fortranmodule.yourfunction()。

您也可以将其导入，

from pythonmodule import fortranmodule
fortranmodule.yourfunction()

否则它可以在我的机器上运行。

Answer 2

为了使 f2py 工作，您需要有一个签名文件来指导界面创建或使用 f2py 注释修改源代码以帮助界面。请参阅 https://numpy.org/doc/stable/f2py/signature-file .html 了解更多信息。

从该站点：

C FILE: FIB3.F
      SUBROUTINE FIB(A,N)
C
C     CALCULATE FIRST N FIBONACCI NUMBERS
C
      INTEGER N
      REAL*8 A(N)
Cf2py intent(in) n
Cf2py intent(out) a
Cf2py depend(n) a
      DO I=1,N
         IF (I.EQ.1) THEN
            A(I) = 0.0D0
         ELSEIF (I.EQ.2) THEN
            A(I) = 1.0D0
         ELSE 
            A(I) = A(I-1) + A(I-2)
         ENDIF
      ENDDO
      END
C END FILE FIB3.F

现在可以通过一个命令来构建扩展模块：

f2py -c -m fib3 fib3.f

Answer 3

要使用 f2py 包装 F90 模块，您需要指定可以从模块外部访问哪些功能。为此，您有 private 和 public fortran90 关键字。您还应该将扩展名从 .f 更改为 .F90 或 .f90。我对您的代码进行了一些更改，以演示 public 和 private 关键字的使用。

首先创建包含模块对象的 Fortran 接口的签名文件：

f2py -h interface.pyf -m module_name module_its.f90 --overwrite-signature

然后编译模块：

f2py interface.pyf -c module_its.f90 

您的代码已修改并命名为 module_its.f90：

module its   
  ! use other modules
  implicit none
  private          ! everything in this module is private by standard 
                   ! (it can be used only inside this F90 module)
  public :: itimes ! Make you subroutine public
 
  contains

  subroutine itimes(infile,outfile)
    ! use other modules here to

    !implicit none holds for everthing in this module

    ! Constants
    integer, parameter :: dp = selected_real_kind(15)

    ! Subroutine Inputs
    character(*), intent(in) :: infile
    character(*), intent(in) :: outfile

    ! Internal variables
    real(dp) :: num
    integer :: inu
    integer :: outu
    integer :: ios

    inu = 11
    outu = 22

    open(inu,file=infile,action='read')
    open(outu,file=outfile,action='write',access='append')

    do
      read(inu,*,IOSTAT=ios) num
      if (ios < 0) exit

      write(outu,*) num**2
    end do

  end subroutine itimes

end module its