在 Mathematica 中使用单个图填充样式

Question

我可以在如下所示的单个图中指定不同的填充颜色，还是需要“显示”多个图？假设我希望填充样式与 PlotStyle 相同。

priorMean = 50;
priorVar = 100;

llhMean = 30;
llhVar = 40;

postMean=35.71;
postVar=28.57;


Plot[
     Evaluate@MapThread[
     Function[{\[Mu], \[Sigma]},
     PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]],
     {{priorMean, llhMean, postMean}, {priorVar, llhVar, postVar}}],
{x, 0, 100}, Filling -> Axis, PlotStyle -> {Red, Green, Blue}]

Answer 1

您需要使用 FillingStyle 来填写。我认为您陷入了 FillingStyle 的语法，它与 FillingStyle 不同。对于 PlotStyle，尽管您希望如此。您必须为每条曲线指定一种颜色 FillingStyle -> {1->颜色1, 2 -> color2} 等。这是一个示例：

colors = {Red, Green, Blue};
Plot[Evaluate@
  MapThread[
   Function[{\[Mu], \[Sigma]}, 
    PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]], {{priorMean, 
     llhMean, postMean}, {priorVar, llhVar, postVar}}], {x, 0, 100}, 
 Filling -> Axis, PlotStyle -> colors, 
 FillingStyle -> 
  MapIndexed[#2 -> Directive[Opacity[0.3], #] &, colors]]

Answer 2

我建议对 Plot 的定义进行扩展。 我之前已经这样做过。

toDirective[{ps__} | ps__] := Flatten[Directive @@ Flatten[{#}]] & /@ {ps}

makefills = MapIndexed[#2 -> Join @@ toDirective@{Opacity[0.3], #} &, #] &;

Unprotect[Plot];
Plot[a__, b : OptionsPattern[]] :=
  Block[{$FSmatch = True},
    With[{fills = makefills@OptionValue[PlotStyle]}, 
      Plot[a, FillingStyle -> fills, b]
  ]] /; ! TrueQ[$FSmatch] /; OptionValue[FillingStyle] === "Match"

完成此操作后，您可以使用 FillingStyle -> “匹配” 自动设置填充样式以匹配主要样式。

Plot[{Sin[x], Cos[x], Log[x]}, {x, 0, 2 Pi},
  PlotRange -> {-2, 2},
  PlotStyle -> {{Blue, Dashing[{0.04, 0.01}]},
                {Thick, Dashed, Orange},
                {Darker@Green, Thick}},
  Filling -> Axis,
  FillingStyle -> "Match"
]

Answer 3

你可以做类似

With[{colours = {Red, Green, Blue}},
 Plot[Evaluate@
   MapThread[
    Function[{\[Mu], \[Sigma]}, 
     PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]], 
     {{priorMean, llhMean, postMean}, {priorVar, llhVar, postVar}}], 
  {x, 0, 100},
  Filling -> 
    MapIndexed[#2[[1]] -> {Axis, Directive[Opacity[.3, #1]]} &, colours], 
  PlotStyle -> colours]]

Answer 4

得到的结果是：

Plot[Evaluate@
  MapThread[
   Function[{\[Mu], \[Sigma]}, 
    PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]], {{priorMean, 
     llhMean, postMean}, {priorVar, llhVar, postVar}}], {x, 0, 100}, 
 Filling -> {1 -> {Axis, Red}, 2 -> {Axis, Green}, 3 -> {Axis, Blue}},
  PlotStyle -> {Red, Green, Blue}]

在帮助中的 FillingStyle、Scope、Filling Style 下找到。

或者：

f = MapThread[
   Function[{\[Mu], \[Sigma]}, 
    PDF[NormalDistribution[\[Mu], Sqrt[\[Sigma]]], x]],
   {{priorMean, llhMean, postMean}, {priorVar, llhVar, postVar}}];
c = {Red, Green, Blue};
Show[Array[
  Plot[f[[#]], {x, 0, 100}, Filling -> {1 -> {Axis, c[[#]]}}, 
    PlotRange -> {Automatic, 0.08}, PlotStyle -> c[[#]]] &, 3]]