如何在perl中使用正则表达式匹配两个实例并替换第一个实例？

Question

如果返回两个匹配项，我只想替换第一个实例。

示例：

$sen = "The quick brown fox jump over the lazy dog, fox is quick";

我怎样才能只匹配第一个fox并将其替换为wolf，反之亦然。

输出：

The quick brown wolf jump over the lazy dog, fox is quick 

或：

The quick brown fox jump over the lazy dog, wolf is quick 

谢谢。

Answer 1

使用全局选项 /g 对匹配进行计数，将匹配列表分配给空列表以获取计数（比临时变量更好）。第一次更换是基本的。第二个使用计数器，该计数器在每次匹配时递增，并在适当的时间替换。

注意使用单词边框\b来防止错误匹配，例如firefox、foxy lady等。

代码：

use strict;
use warnings;
use v5.10;   # only required for say, use print instead if your version is lower

my $fox  = 'fox';
my $wolf = 'wolf';
my $sen = "The quick brown fox jump over the lazy dog, fox is quick";

if ((()=$sen =~ /\b$fox\b/g) == 2) {   # counting matches 
    my $first = $sen;
    $first =~ s/\b$fox\b/$wolf/;       # replacing first
    my $second = $sen;
    my $i = 0;
    $second =~ s/\b$fox\b/ ++$i == 2 ? $wolf : $fox/eg;  # replacing second
    say for $first, $second;
}

输出：

The quick brown wolf jump over the lazy dog, fox is quick
The quick brown fox jump over the lazy dog, wolf is quick

如果您想要更可重用的代码，您可以用它制作一个子例程。

my $second = replace_nr($sen, $fox, $wolf, 2);
...
sub replace_nr {
    my ($str, $find, $replace, $num) = @_;
    my $i = 0;
    $str =~ s/\b($find)\b/ ++$i == $num ? $replace : $find/eg;
    return $str;
}

然后你甚至可以使用 sub 来进行这两种替换：

my $first  = replace_nr($sen, $fox, $wolf, 1);
my $second = replace_nr($sen, $fox, $wolf, 2);

Answer 2

检查是否有（至少）两个并替换第一个：

# The quick brown *wolf* jump over the lazy dog, fox is quick
s/fox(?=.*fox)/wolf/s;

检查是否有（至少）两个并替换第二个：

# The quick brown fox jump over the lazy dog, *wolf* is quick:
s/fox.*\Kfox/wolf/s;

s/(fox.*)fox/${1}wolf/s;  # Slower, but works pre 5.10

Answer 3

默认情况下，替换运算符的作用正是：匹配并替换第一次出现的情况。

以下语句将为您提供第一条输出行：

s/wolf/fox/

Answer 4

您的新问题是您想要计数

my $count = () = $text =~ /fox/g;

并替换第 N 个实例

my $n = 3;
my $nm1 = $n-1;
$text =~ s/(?:fox.*){$nm1}\Kfox/s;