Perl：使用循环还是 Map/Grep？

Question

我正在编写一个程序来逐步浏览目录树（是的，我知道 File::Find，但我正在编写一个替代程序）。

在我的程序中，我对整个目录执行 readdir 并将其放入列表中。我需要做两件事：

1. 从列表中删除 . 和 ..
2. 在每个文件上添加当前目录名称。

我可以使用循环来完成此操作，也可以使用 map 和 grep：

# Map and Grep

my @dir_stack = readdir $dir_fh;;
@dir_stack = grep { !/^\.{1,2}$/ } @dir_stack;
@dir_stack = reverse map { "$cwd/$_" } @dir_stack;
push @stack, @dir_stack;

# Read Loop

opendir $dir_fh, $cwd;
my @dir_stack;
foreach my $file (readdir $dir_fh) {
    next if $file =~ /^\.{1,2}$/;   #Skip "." and ".."
    unshift @dir_stack, "$cwd/$file";
}
push @stack, @dir_stack;

将 grep 和 map 结合起来怎么样？ ？

 opendir $dir_fh, $cwd;
 my @dir_stack = readdir $dir_fh;;
 @dir_stack = grep { !/^\.{1,2}$/ && {$_ = "$cwd/$_"} } @dir_stack;
 push @stack, reverse @dir_stack;

我希望下周当我查看代码并尝试弄清楚发生了什么时，它可以可读。我还需要我的代码高效。

Answer 1

在grep中修改$_？哎呀！使用匿名哈希构造函数有什么用？

@dir_stack = grep { !/^\.{1,2}$/ && {$_ = "$cwd/$_"} } @dir_stack;

应该是

@dir_stack = map { /^\.\.?\z/ ? () : "$cwd/$_" } @dir_stack;

但是我个人发现同时使用map和grep比组合它们更具可读性。

push @stack,
   reverse
    map "$cwd/$_",
     grep !/^\.\.?\z/,
      readdir $dh;

对 reverse 的需求相当奇怪，而且它在这里比隐藏为 unshift 更明显，所以这是另一个好处。

Answer 2

为了使您的代码更具可读性，您只需要再添加一行:

# exclude '.' and '..', and prepend dir name to each elem in @dir_stack

:-)

Answer 3

听起来您可能需要 glob 代替。尽管我相信它将排除所有以 . 开头的文件（即隐藏文件），而不仅仅是 . 和 ..。当然，路径中不能有空格。

my @stack = glob "$dir_fh/*";

只要你喂它一条路径，它就会返回。