如何在给定不完全包含在单词中的标记的情况下对单词进行标记？

Question

我了解如何按以下方式在 Perl 中使用正则表达式：

$str =~ s/expression/replacement/g;

我了解如果表达式的任何部分括在括号中，则可以在替换部分中使用和捕获它，如下所示：

$str =~ s/(a)/($1)dosomething/;

但是有没有办法捕获 < code>($1) 位于正则表达式的外部之上？

我有一个完整的单词，它是一串辅音，例如 bEdmA，它的元音版本 baEodamaA （其中 a 和 o 是元音），以及由空格分隔的两个标记的分割形式，bEd maA。我只想从完整的单词中提取标记的元音形式，如下所示：beEoda、maA。我正在尝试捕获完整单词表达式中的标记，因此我有：

$unvowelizedword = "bEdmA";
$tokens[0] = "bEd", $tokens[1] = "mA";
$vowelizedword = "baEodamA";

foreach $t(@tokens) {
    #find the token within the full word, and capture its vowels
}

我正在尝试执行以下操作：

$vowelizedword = m/($t)/;

这是完全错误的，原因有两个：标记 $t 不存在完全以其自己的形式，例如 bEd，但类似 ​​m/bEd/ 的内容会更相关。另外，如何在正则表达式外部的变量中捕获它？

真正的问题是：在给定标记 bEd、mA 的情况下，如何捕获元音序列 baEoda 和 maA来自完整单词beEodamaA？

---

编辑

我从所有答案中意识到我错过了两个重要的细节。

1. 元音是可选的。因此，如果标记是：“Al”和“ywm”，并且完全元音化的单词是“Alyawmi”，则输出标记将是“Al”和“yawmi”。

2. 我只提到了两个元音，但还有更多，包括由两个字符组成的符号，例如“~a”。完整列表（尽管我认为我不需要在这里提及）是：

   @元音 = ('a', 'i', 'u', 'o', '~', '~a', '~i', '~u', 'N', 'F', 'K', '~N', '~K');

Answer 1

以下似乎可以满足您的要求：

#!/usr/bin/env perl
use warnings;
use strict;

my @tokens = ('bEd', 'mA');
my $vowelizedword = "beEodamaA";

my @regex = map { join('.?', split //) . '.?' } @tokens;

my $regex = join('|', @regex);
$regex = qr/($regex)/;

while (my ($matched) = $vowelizedword =~ $regex) {
    $vowelizedword =~ s{$regex}{};
    print "matched $matched\n";
}

根据您更新的问题进行更新（元音是可选的）。它从字符串末尾开始工作，因此您必须将标记收集到一个数组中并反向打印它们：

#!/usr/bin/env perl
use warnings;
use strict;

my @tokens = ('bEd', 'mA', 'Al', 'ywm');
my $vowelizedword = "beEodamaA Alyawmi"; # Caveat: Without the space it won't work.

my @regex = map { join('.?', split //) . '.?
 } @tokens;

my $regex = join('|', @regex);
$regex = qr/($regex)/;

while (my ($matched) = $vowelizedword =~ $regex) {
        $vowelizedword =~ s{$regex}{};
            print "matched $matched\n";
}

Answer 2

在所谓的“列表上下文”中使用 m// 运算符，如下所示：

my @tokens = ($input =~ m/capturing_regex_here/modifiershere);

Answer 3

ETA：据我现在的了解，您想说的是您想要在标记的每个字符后面匹配一个可选的元音。

这样，您可以调整 $vowels 变量以仅包含您要查找的字母。或者，您也可以只使用 . 来捕获任何字符。

use strict;
use warnings;
use Data::Dumper;

my @tokens = ("bEd", "mA");
my $full = "baEodamA";

my $vowels = "[aeiouy]";
my @matches;
for my $rx (@tokens) {
    $rx =~ s/.\K/$vowels?/g;
    if ($full =~ /$rx/) {
        push @matches, $full =~ /$rx/g;
    }
}

print Dumper \@matches;

输出：

$VAR1 = [
          'baEoda',
          'mA'
        ];

请注意，

... $full =~ /$rx/g;

不需要捕获组< /a> 在正则表达式中。

Answer 4

我怀疑有一种更简单的方法可以完成您想要完成的任何事情。诀窍是不要让正则表达式生成代码太复杂，以至于你忘记它实际上在做什么。

我只能开始猜测您的任务，但从您的单个示例来看，您似乎想检查两个子标记是否在较大的标记中，而忽略某些字符。我猜测这些子标记必须按顺序排列，并且除了那些元音字符之外，它们之间不能有任何其他内容。

为了匹配标记，我可以在标量上下文中使用 \G 锚点和 /g 全局标志。这会将匹配锚定到同一标量的最后一个匹配结束后的字符。这种方式允许我为每个子标记拥有单独的模式。这更容易管理，因为我只需要更改 @subtokens 中的值列表。

一旦你检查了每一对并找到哪些与所有模式匹配，我就可以从这对中提取原始字符串。

use v5.14;

my $vowels    = '[ao]*';
my @subtokens = qw(bEd mA);

# prepare the subtoken regular expressions
my @patterns = map {
    my $s = join "$vowels", map quotemeta, (split( // ), '');
    qr/$s/;
    } @subtokens;

my @tokens = qw( baEodamA mAabaEod baEoda mAbaEoda );

my @grand_matches;
TOKEN: foreach my $token ( @tokens ) {
    say "-------\nMatching $token..........";
    my @matches;
    PATTERN: foreach my $pattern ( @patterns ) {
        say "Position is ", pos($token) // 0;

        # scalar context /g and \G
        next TOKEN unless $token =~ /\G($pattern)/g; 
        push @matches, $1;
        say "Matched with $pattern";
        }
    push @grand_matches, [ $token, \@matches ];
    }

# Now report the original   
foreach my $tuple ( @grand_matches ) {
    say "$tuple->[0] has both fragments: @{$tuple->[1]}";
    }

现在，这是这个结构的好处。我可能对你的任务猜错了。如果有的话，很容易修复，无需更改设置。假设子标记不必按顺序排列。这是对我创建的模式的简单更改。我只是摆脱了
\G 锚点和 /g 标志；

        next TOKEN unless $token =~ /($pattern)/; 

或者，假设令牌必须按顺序排列，但它们之间可能存在其他因素。我可以插入一个 .*? 来匹配这些内容，从而有效地跳过它：

        next TOKEN unless $token =~ /\G.*?($pattern)/g; 

如果我可以从我创建的 map 中管理所有这些，那就更好了模式，但 /g 标志不是模式标志。它必须与操作员一起。

我发现，当我不将所有内容都包含在单个正则表达式中时，管理不断变化的需求会容易得多。

Answer 5

假设标记需要按顺序出现并且它们之间没有任何内容（元音除外）：

my @tokens = ( "bEd", "mA" );
my $vowelizedword = "baEodamaA";

my $vowels = '[ao]';
my (@vowelized_sequences) = $vowelizedword =~ ( '^' . join( '', map "(" . join( $vowels, split( //, $_ ) ) . "(?:$vowels)?)", @tokens ) . '\\z' );
print for @vowelized_sequences;