自动允许 Ctrl+A 选择 TMemo 中的所有内容？

Question

在 Delphi 7 的 TMemo 控件中，尝试使用组合键 Ctrl + A 来选择全部不会执行任何操作（不会选择全部）。所以我做了这个程序：

procedure TForm1.Memo1KeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
var
  C: String;
begin
  if ssCtrl in Shift then begin
    C:= LowerCase(Char(Key));
    if C = 'a' then begin
      Memo1.SelectAll;
    end;
  end;
end;

有什么技巧可以让我不必执行这个程序吗？如果没有，那么这个过程看起来还可以吗？

Answer 1

这是更优雅的：

procedure TForm1.Memo1KeyPress(Sender: TObject; var Key: Char);
begin
  if Key = ^A then
  begin
    (Sender as TMemo).SelectAll;
    Key := #0;
  end;
end;

Answer 2

虽然 Andreas Rejbrand 接受的答案是正确的，但这不是预期的 Windows 视觉行为。它使光标位置保持不变。 Ctrl-A（全选）应将光标保留在文本底部并滚动控件，以便光标位于视图中。

如果不这样做，控件就会表现出奇怪的行为。例如，假设文本超出了窗口的容纳范围，并且窗口没有滚动到底部。按 Ctrl-A，所有文本都会被选中。 Ctrl-C 现在会将所有文本复制到剪贴板。尽管您看不到它，但光标现在位于视图的底部，该视图尚未滚动。如果您现在按下 Ctrl-Down，所选文本将变为视图中的文本，然后光标向下移动，窗口向下滚动一行。新的底线未被选择。这使得“全选”看起来只选择了可见文本。

解决方法是将插入符号移至 SelectAll 之前的文本末尾。

procedure TForm1.Memo1KeyPress(Sender: TObject; var Key: Char);
begin
  if Key = ^A then begin
    With Sender as TMemo do begin
      SelStart := Length(Text);
      Perform(EM_SCROLLCARET, 0, 0);
      SelectAll;
    end;
    Key := #0;    //Eat the key to suppress the beep
  end;
end;

请注意，“吃掉钥匙”仅适用于 OnKeyPress 事件，不适用于 OnKeyDown 或 OnKeyUp 事件。

Answer 3

我使用前面的答案和讨论来创建一个独立的组件，用于处理我在小型测试程序中使用的 KeyPress 事件。

TSelectMemo = class(TMemo)
protected
  procedure KeyPress(var Key: Char); override;
end;

...

procedure TSelectMemo.KeyPress(var Key: Char);
begin
  inherited;
  if Key = ^A then
    SelectAll;
end;

向表单上的所有组件添加“全选”行为的另一种方法是使用标准全选操作将操作列表添加到表单。