使用什么样的可变参数函数？

Question

我想编写一个可变参数函数，该函数应该有 1 个不可选的字符串类型参数和第二个可选字符串。我已经阅读了有关可变参数函数的语言规范，但考虑到 D 的许多选项，我想知道哪个是适合我的问题的解决方案。

另外，我应该如何使用强制转换和指针来复制 void* _argptr 指向的字符串（我猜字符串在 D 中是不可变的这一事实让我感到困惑）。

编辑：我想要的是：

string foo (string nonopt, ...) { /*code*/ }

//...
string a = "[email protected]", b = "a.t";
auto s = foo(a);
auto s2 = foo(a, b);

Answer 1

你所要求的听起来一点也不可变。您确切地知道应该有多少个参数 - 1 或 2。在这种情况下，只需使用第二个参数的默认参数。例如，

void func(string required, string optional = null) {}

如果您想要的是一个 string 后跟未知数量的字符串，那么您可能想要执行类似

void func(string required, string[] optional...)

If 的操作，另一方面，您想要的是需要 >string 后跟未知数量的各种类型的参数，那么您想要的是 可变参数模板。

void func(T...)(string required, T optional) {}

Answer 2

你想要类似的东西吗：

void foo(string required, string optional = "") {}

或者也许像（未经测试）：

class Optional(T) {
  private T _val;
  public this(in T val) { _val = val; }
  @property public T get() { return _val; }
}

void foo(string required, Optional!(string) = null) {}

Answer 3

下面是一个 foo() 的示例，它完全按照您在 OP 中的要求进行操作，另外还有 foovar() 函数，它可以接受任意数量的参数。在本例中，我只接受字符串参数，但您可以更改代码以接受任何内容。

import std.stdio;
import core.vararg;

string foo (string nonopt, string opt = "") {
  string ret;
  if (opt.length == 0)
    ret = nonopt;
  else
    ret = nonopt ~ ";" ~ opt;

  return ret;
} // foo() function

string foovar(string nonopt, ...) {
  string ret = nonopt ~ "/";
  for (int i = 0; i < _arguments.length; i++) {
    // we want to use only string arguments to build the result
    if (_arguments[i] == typeid(string)) {
      ret ~= va_arg!(string)(_argptr) ~ "/";
    } // if
  } // for
  return ret;
} // foovar() function

int main() {
  string a = "[email protected]", b = "a.t";
  auto s = foo(a);
  auto s2 = foo(a, b);
  auto s3 = foovar(a, "D", "rules");
  writeln(s);   // [email protected]
  writeln(s2);  // [email protected];a.t
  writeln(s3);  // [email protected]/D/rules/
  return 0;
} //  main() function

Answer 4

您可以执行 C 风格的可变参数函数，在这种情况下，请查看 core.vararg。首选的 D 解决方案是使用模板化函数：

import std.stdio;

void foo(Args...)(string first, Args args)
{
    writeln("First argument is ", first);
    foreach (i, A; Args)
    {
        writefln("Type of %s argument is %s, value is %s",
                    i, A.stringof, args[i]);
    }
}

void main(){
    foo("bar", 1, 4.0, false);
}     

Answer 5

下面的做法不行吗？

void myFunction(string nonOptionalParameter, string optionalParameter="default value")
{
  // Your code here
}