如何将 Getopt::Long 选项传递给也是一个选项的子例程？

Question

我正在尝试设置 Getopt::Long 来处理配置脚本中的参数。

这是我的开场白：

#!/usr/bin/perl
use strict;
use warnings;
use Getopt::Long;

my $config_file = '';

GetOptions (    
    'config|c=s' => \$config_file,
    'add|a' => \&add_server,
    'del|d' => \&del_server,        
);

sub add_server {    
    print "$config_file\n";    
}

sub del_server {    
    # Left blank for now.    
}

奇怪的是，当我使用如下命令运行脚本时，我遇到了问题：

./config.pl -a -c config.xml

它不会打印 < code>-c 选项，但如果我像这样运行它，

./config.pl -c config.xml -a

它会像它应该的那样工作。

我想我明白其中的原因；这与订单执行有关吗？

我该如何修复它？我应该将 Getopt::Long 与 @ARGV 结合使用吗？

最终，我试图将命令行参数传递到我正在调用的子例程中。因此，如果 -a 或 --add，我希望传递 -c 或 --config 的选项调用时进入子程序。

有什么想法吗？

Answer 1

启用 Getopt::Long 上的 pass_through 选项，以便它将忽略未知选项，然后为您的选项调用一次 GetOptions，再次禁用它，然后再次为您的命令使用 GetOptions。

Answer 2

GetOptions(
        'arg=s' => sub { print "$_[1]\n"; },
);

Answer 3

我认为没有必要直接从 GetOptions 调用中调用子例程。像这样控制顺序：

use strict;
use warnings;
use Getopt::Long;

my %opts = (config => '');

GetOptions(\%opts, qw(
   config|c=s
   add|a
   del|d
));

add_server() if $opts{add};
del_server() if $opts{del};

sub add_server {    
    print "$opts{config}\n";
}

sub del_server {}

Answer 4

将示例稍微简化一下......

use strict;
use warnings;
use Getopt::Long;

my $config_file = '';

GetOptions (

    'config|c=s' => \$config_file,
    'add|a' => sub{add_server($config_file);}
);

sub add_server
{

    my $config=shift;

    if(defined($config))
    {
        print "Got this for a config file: $config\n";
    }
    else
    {
        print "No argument supplied to add_server\n";
    }

}

并运行config.pl -c Blug -a返回输出Got this for a config file:blurg，并且运行 config.pl -a -c blurg 会返回 Got this for a config file:。

所以，我怀疑正在发生的事情是选项是按照给定的顺序分配的。因此，在第一种情况下，$config_file 被分配给 -c 参数，然后调用 add_server 子例程（使用正确的参数），而在第二种情况下，add_server 立即被触发，不带任何参数，然后分配 $config_file。

除此之外，我建议将 -a 设置为布尔值，并在启用它的情况下执行您想做的任何操作（并且如果提供了 -c 的参数）。

Answer 5

遇到选项时会调用回调，因此当您执行操作时，会在遇到 -c 之前调用 add_server

./config.pl -a -c config.xml

根据最新信息，您现在需要：

use Getopt::Long qw( GetOptions );

GetOptions(
   'a=s' => \my $opt_a,
   'd=s' => \my $opt_d,
   'h=s' => \my $opt_h,
   'p=s' => \my $opt_p,
) or usage();