仅当安装了所需的模块时，如何才能在 Perl 模块的测试套件中运行测试？

Question

我想向我的 Perl 发行版添加一个需要模块 Foo 的测试，但我的发行版不需要 Foo；只有测试需要 Foo。所以我不想将模块添加到依赖项中，而是如果 Foo 在构建时不可用，我只想跳过需要 Foo 的测试。

执行此操作的正确方法是什么？我是否应该将 Foo 测试与 use Foo; 一起包装在 eval 块中，以便在加载 Foo 失败时测试不会运行？或者有更优雅的方法吗？

Answer 1

如果需要 Some::Module 的所有测试都在一个文件中，那么很容易做到：（

use Test::More;

BEGIN {
    eval {
        require Some::Module;
        1;
    } or do {
        plan skip_all => "Some::Module is not available";
    };
}

如果您使用像 use Test::Moretests => 这样的测试计数; 42; 那么您还需要安排进行计划测试 => 42;（如果要求成功）。

）包含其他内容的文件中的测试，然后你可以这样做：

our $HAVE_SOME_MODULE = 0;

BEGIN {
    eval {
        require Some::Module;
        $HAVE_SOME_MODULE = 1;
    };
}

# ... some other tests here

SKIP: {
    skip "Some::Module is not available", $num_skipped unless $HAVE_SOME_MODULE;
    # ... tests using Some::Module here
}

Answer 2

如果不满足某些条件，Test::More 可以选择跳过，请参见下文

SKIP: {
    eval { require Foo };

    skip "Foo not installed", 2 if $@;

    ## do something if Foo is installed
};

Answer 3

从 Test::More 的文档中：

SKIP: {
    eval { require HTML::Lint };
    skip "HTML::Lint not installed", 2 if $@;
    my $lint = new HTML::Lint;
    isa_ok( $lint, "HTML::Lint" );
    $lint->parse( $html );
    is( $lint->errors, 0, "No errors found in HTML" );
}

Answer 4

另外，声明您的测试步骤要求或建议（存在差异）发行版元文件。这将由执行安装的客户端获取。在安装时，用户可以决定是永久安装这样的需求还是放弃它，因为它仅用于测试。