通过 VBA 添加新值时，MS Project 会更改分配的工作值

Question

使用 MS Project 2007 时遇到 VBA 问题。我有一个任务 Task，有 2 个作业，包括资源 Foo（2 天的工作）和 Bar（工作5天）。 任务设置为固定工作。现在，当向任务手动添加额外的任务或从任务中手动删除任务时，一切都按预期工作，没有什么奇怪的事情发生。使用 VBA 时，如下所示，其他作业的工作值会发生变化。

' Adding an Assignment with the "Baz" Resource and 10d of work
Sub AddAssignment()
    Dim tskTask As Task
    Dim rsResource As Resource
    Dim asAssignment As Assignment

    Set tskTask = ActiveProject.Tasks(1)
    Set rsResource = ActiveProject.Resources("Baz")
    Set asAssignment = tskTask.Assignments.Add(tskTask.ID, rsResource.ID)
    asAssignment.Work = "10d"
End Sub

在执行脚本之前：

Task:
  Foo 16h
  Bar 40h

在执行脚本之后：

Task:
  Foo 9,33h
  Bar 23,33h
  Baz 80h

那么，实际问题是，为了保持其他作业的工作值，我必须做些什么不同的事情？

Answer 1

实际上更简单的问题是努力驱动的。将任务设置为固定单位并减少工作量，原始代码可以正常工作。

Answer 2

由于任务设置为“固定工时”，因此当您添加资源分配时，任务的总工时将保持不变。当您想要添加资源并增加任务的总工作量时，就会出现问题。

在本例中，总工作时间为 56 小时。你添加一个作业，总工时仍然是 56 小时。工作比例相同：40%、100% 和 100%，分别为 9.33 小时、23.33 小时和 23.33 小时。然后，最后一次作业的工时增加到 80 小时，任务的总工时现在为 112.67 小时。

它在用户界面中按照您的预期工作的原因是，您不仅添加了新的分配并设置其工作，而且从 MS Project 的角度来看，您还（重新）设置了现有资源的工作。

在 VBA 中执行此操作的解决方案是准确模拟 UI 中发生的情况，其中包括重置现有资源的工作：

Sub AddAssignment()
    Dim tskTask As Task
    Dim rsResource As Resource
    Dim asAssignment As Assignment
    Dim colAssn As Collection
    Dim iIdx As Integer

    Set tskTask = ActiveProject.Tasks(7)
    Set rsResource = ActiveProject.Resources("Baz")
    Set colAssn = New Collection
    For Each asAssignment In tskTask.Assignments
        colAssn.Add asAssignment.Work
    Next asAssignment
    Set asAssignment = tskTask.Assignments.Add(tskTask.ID, rsResource.ID)
    colAssn.Add 10 * 8 * 60 ' work is stored as minutes
    For iIdx = 1 To colAssn.Count
        tskTask.Assignments(iIdx).Work = colAssn(iIdx)
    Next iIdx
End Sub