实现 IEnumerable当基类实现 IEnumerable 时

Question

是否有一种简洁的方法可以在基类型实现非泛型 IEnumerable 的类型中实现 IEnumerable<'T>？我正在使用下面的 mkEnumerator 函数来执行此操作，但它似乎过多。

open System
open System.Collections.Generic
open System.Configuration

let mkEnumerator<'T> (e : System.Collections.IEnumerator) =
  { new IEnumerator<'T> with
      member __.Current = e.Current |> unbox
    interface System.Collections.IEnumerator with
      member __.Current = e.Current
      member __.MoveNext() = e.MoveNext()
      member __.Reset() = e.Reset()
    interface IDisposable with
      member __.Dispose() =
        match e with
        | :? IDisposable as d -> d.Dispose()
        | _ -> () }

type MyConfigElement() = 
  inherit ConfigurationElement()

type MyConfigCollection() =
  inherit ConfigurationElementCollection()
  override __.CreateNewElement() = Unchecked.defaultof<_>
  override __.GetElementKey(_) = Unchecked.defaultof<_>
  interface IEnumerable<MyConfigElement> with
    member __.GetEnumerator() = mkEnumerator<MyConfigElement> (base.GetEnumerator())

更新

按照 desco 的建议，我现在使用：

type MyConfigCollection() =
  inherit ConfigurationElementCollection()
  ...
  interface IEnumerable<MyConfigElement> with
    member __.GetEnumerator() = (Seq.cast<MyConfigElement> this).GetEnumerator()

Answer 1

布莱恩建议的简短版本：

let mkEnum<'T> (ie : System.Collections.IEnumerable) = (Seq.cast<'T> ie).GetEnumerator()

Answer 2

我认为你的方式看起来最好。我想这更简洁（我没有尝试端到端以确保它有效）：

let mkEnum<'T>(ie : System.Collections.IEnumerable) 
                       : System.Collections.Generic.IEnumerator<'T> =
    (seq { for x in ie -> unbox x }).GetEnumerator()

但我想知道它是否分配更多。

正如@desco 所指出的，这甚至更短：

let mkEnum<'T> ie = (Seq.cast<'T>(ie)).GetEnumerator()