我们如何使用 perl 对第 1 列和第 2 列用户数据进行排序

Question

我是 Perl 编程新手。 我想读取文件数据，然后对第 1 列和第 2 列上的记录进行排序（删除重复记录）并将排序后的记录存储到另一个文件中。以下是我的数据

第一列和第二列由制表符分隔

 user1 name       user2 name

    abc               xyz
    adc               xyz
    abc               xyz
    pqr               tyu
    xyz               abc
    tyu               pqr
    abc               pqr

在此示例中，我希望首先对 user1 名称排序记录，然后对 user2 名称排序，并且在排序时我想删除重复的记录。

输出应如下所示，

user1 name        user2 name
  abc              pqr
  abc              xyz
  adc              xyz
  pqr              tyu
  tyu              pqr
  xyz              abc

请让我知道我们如何实现这个 perl？

Answer 1

#!/usr/bin/env perl
use strict;
use warnings;
my @list = <DATA>;
my $prev;
for (sort @list) {
    next if $prev && $_ eq $prev;
    $prev = $_;
    print;
}
__DATA__
    abc               xyz
    adc               xyz
    abc               xyz
    pqr               tyu
    xyz               abc
    tyu               pqr
    abc               pqr

Answer 2

这完全取决于您如何存储数据。我不确定您打算如何存储您的信息，因为您在课堂上并且可能已经或可能没有了解参考资料。例如，如果您不知道引用，您可能会执行以下操作：

my @array;
foreach my $value (<INPUT>) {
   chomp $value;
   my ($user1, $user2) = split (" ", $value);
   push (@array, "$user1:$user2");
}

这会将两个值存储为单个字符串。如果不了解参考资料，这种情况很常见。

如果您了解引用，您可能会这样做：

my @array;
foreach my $value (<INPUT>) {
   chomp $value;
   my @line = split (" ", $value);
   push (@array, \@line);
}

我可以告诉您的是 sort< /a> 子例程允许您创建一个函数来比较和排序值。当您在 sort 中使用自己的函数时，您会得到两个值 $a 和 $b ，它们代表您要排序的值。您可以操作它们，然后如果 $a 小于 $b 或 1，则返回 -1如果 $a 大于 $b 或如果两者相等则返回零。 Perl 为您提供了两个运算符 <=> 和 cmp 以使此操作变得更容易。

假设您将值存储为 $user1:$user2，因为您尚未了解引用。您的排序例程可能如下所示。

sub sort {
    my ($a_col1, $a_col2) = split (/:/, $a);
    my ($b_col1, $b_col2) = split (/:/, $b);

    # Now we compare $a to $b. First, we can compare the
    # User 1 column:

    if ($a_col1 lt $b_col1) {
        return -1;    #$a < $b
    }
    elsif ($a_col1 gt $b_col1) {
        return 1;     #$a > $b
    }

    # If we're down here, it's because column 1 matches
    # for both $a and $b. We'll have to compare column #2
    # to see which one is bigger.

    if ($a_col2 lt $b_col2) {
       return -1;   #$a < $b
    }
    elsif ($a_col2 gt $b_col2) {
       return 1;    #$a > $b
    }

    #We're down here because both column #1 and column #2 match for both
    #$a and $b. They must be equal

    return 0;
}

现在，我的排序将如下所示：

my @new_array = sort(\&sort, @array);

注意：这不是我个人的做法。我可能会使用内置的 cmp 运算符并采取一些快捷方式。不过，我想把它一点一点地拆开，这样你就可以理解了。

顺便说一句，如果老师决定您应该在第一列之前对第二列进行排序，您可以通过更改周围的小于和大于符号来轻松修改您的 sort 子例程。

---

这是我的测试程序：

#! /usr/bin/env perl

use strict;
use warnings;

#Putting my data in `@array`

my @array;
foreach my $entry (<DATA>) {
    chomp $entry;
    my ($user1, $user2) = split " ",  $entry;
    push @array, "$user1:$user2";
}

# Sorting my data

my @new_array = sort \&sort, @array;

#Now printing out my data nice and sorted...

foreach my $element (@new_array) {
    my ($user1, $user2) = split (/:/, $element);
    print "$user1\t\t$user2\n";
}

#
# END OF PROGRAM
##################################################

##################################################
# Sort subroutine I'm using to sort the data
#
sub sort {
    my ($a_col1, $a_col2) = split (/:/, $a);
    my ($b_col1, $b_col2) = split (/:/, $b);

    # Now we compare $a to $b. First, we can compare the
    # User 1 column:

    if ($a_col1 lt $b_col1) {
        return -1;    #$a < $b
    }
    elsif ($a_col1 gt $b_col1) {
        return 1;     #$a > $b
    }

    # If we're down here, it's because column 1 matches
    # for both $a and $b. We'll have to compare column #2
    # to see which one is bigger.

    if ($a_col2 lt $b_col2) {
        return -1;   #$a < $b

   }
    elsif ($a_col2 gt $b_col2) {
        return 1;    #$a > $b
    }

    #We're down here because both column #1 and column #2 match for both
    #$a and $b. They must be equal

    return 0;
}

__DATA__
david       fu
david       bar
albert      foofoo
sandy       barbar
albert      foobar

Answer 3

也许不值得生产代码，但这里有一个方法：

#!/usr/bin/perl

use strict;
use warnings;

my %seen;
print join "",
    grep {$_ !~ /^\s+$/ && !$seen{$_}++}
    sort {$a !~ /^ user/ <=> $b !~ /^ user/ || 
    $a cmp $b} <DATA>;

__DATA__
 user1 name       user2 name

    abc               xyz
    adc               xyz
    abc               xyz
    pqr               tyu
    xyz               abc
    tyu               pqr
    abc               pqr

输出：

 user1 name       user2 name
    abc               pqr   
    abc               xyz
    adc               xyz
    pqr               tyu
    tyu               pqr
    xyz               abc

这里最非常规的部分是 $a !~ /^ user/ <=>; $b !~ /^ user/ 排序条件。 $a !~ /^ user/ 对除第一行之外的所有行计算 1 (true)，第一行的计算结果为 0 (false) ，因此标题被放在第一位，尾随行则进入第二个排序条件，从而产生所需的结果。

Answer 4

或者它可以像这样简单：

print sort <DATA>;

__DATA__
    abc xyz
    pqr tyu
    xyz abc
    adc xyz
    tyu pqr
    abc pqr
    abc xyz

但前提是您的数据像这样简单。如果每列中的数据长度不同，
每列的宽度必须与最长的项目一样宽。像这样：

__DATA__
    abc              |xyz       |<-- other data in record...
    pqrwf            |tyu       |<-- other data in record...
    xyzsder          |abc       |<-- other data in record...
    adca             |xyzghrt   |<-- other data in record...
    tyuvdfcg         |pqr       |<-- other data in record...
    abcvfgfaqrt      |pqrbb     |<-- other data in record...
    abcaaaaaaaaaaa   |xyz       |<-- other data in record...

在这种情况下，简单排序仍然有效，但请注意，这些列是用空格而不是制表符填充的。