可以使用 Perl 的 grep 和 regex 返回捕获

Question

是否可以使用 Perl 的 grep 函数仅返回正则表达式的捕获部分？我有如下代码：

use LWP::Simple;
my $examples_content = get('http://example.com/javascript/reports/examples/');
my @hrefs = grep(/href="(.*)"/, split("\n", $examples_content));
print $hrefs[0];

打印的内容是：

独立的单问题图表

当我想要时： simple_chart.html

Answer 1

你为什么使用grep？这可能会做你想要的：

my @hrefs = $examples_content =~ /href="(.*?)"/g

Answer 2

有人已经在评论中提到了这一点，但是如果您正在处理 HTML，我有一个提取链接的模块。如果您不介意依赖 HTML::Parser，那么它并不是一个糟糕的小工具：

    use HTML::SimpleLinkExtor;

    my $extor = HTML::SimpleLinkExtor->new;
    $extor->parse($html);

    @a_hrefs     = $extor->a;    # by tag
    @hrefs       = $extor->href; # by attribute

我主要使用这个模块来完成快速而肮脏的工作。由于它使用真正的 HTML 解析器，因此不会提取误报，例如文本中的类似内容（标签内部）。

大多数其他人已经解决了 map 和 split 的问题，但您也需要小心正则表达式：

 my @hrefs = map {
      / \s href \s* = \s* (['"]) (.*?) \1 /ix ? $2 : ()
     } @lines;

您可以看到不同的引用字符（或根本没有），以及不区分大小写的标签和属性。无论任何规范或标准如何规定，很多东西都会生成混乱的 HTML，并且许多浏览器都支持它。我可能仍然缺少那种模式中的东西。这就是我编写该模块的原因。

Answer 3

grep 可能不是适合这项工作的工具。尝试只是 $examples_content =~ /href="(.*?)"/g ...不需要先 split 和 ? 修饰符将防止 href=".*" 模式匹配太多。

Answer 4

map 可以通过返回或不返回值来轻松模拟 grep：

my @hrefs = map(/href="(.*?)"/g, split("\n", $examples_content));

但我同意 Amadan 和 BRPocock 的观点在这种情况下，删除拆分并仅与源进行匹配会效果更好，但我将其添加为答案，以向您展示如何将 map 用于其他情况。

本着不止一种方法的精神，行：

my @hrefs = $examples_content =~ /href="(.*?)"/g;

也可以写成：

my @hrefs = map /href="(.*?)"/g, $examples_content;

如果您更喜欢顺序[输出变换输入]而不是[输出输入变换] >