如何在 Mathematica 中制作选择性下拉菜单？

Question

我的 Manipulate 界面空间不足。因此，我想看看是否可以重载 PopupMenu 来满足多个目的。

问题是：

我有一个弹出菜单，我用它来从中选择一个条目。但根据我在其他地方所做的另一个选择，菜单中的某些条目将不再有意义。

所以，我想知道，是否可以根据动态设置使 PopupMenu 中的某些条目“可选择”？ （可能被禁用，或变灰，或者最好的办法是，让整个列表本身是动态的，即整个弹出菜单是动态的，这样我就可以根据另一个动态的值选择不同的菜单。但我不认为这是是可能的）

目前，可以根据动态设置启用或禁用整个 PopupMenu。但我想在弹出菜单内的入门级执行此操作。

下面举个例子来说明：

Manipulate[selection,
 Grid[{
   {"x", SetterBar[Dynamic[x], {1, 2}]},
   {"selection", PopupMenu[Dynamic[selection],
     {
      "NONE", "SOR", "SSOR"
      }, Enabled -> Dynamic[x == 1]], SpanFromLeft
    }
   }]
 ]

在此处输入图像描述"> 上面，当X=1时，整个菜单被启用。

但我想要的是，如果 X=1，则只能选择“NONE”（或者列表仅显示“NONE”），而当 X=2 时，则只能选择“SOR”和“SSOR” “（或者列表只显示这两个选择）。

即如果x=2，系统将不会选择“SOR”。尝试选择它不会导致任何更改，并且菜单将保留其先前的设置并且不会更改。

再说一遍，我知道我可以将内容分成 2 个 popuMenus，并根据 X 设置控制每个菜单，如下所示，但我没有更多空间来添加更多菜单：

Manipulate[If[x == 1, selectionA, selectionB],
 Grid[{
   {"x", SetterBar[Dynamic[x], {1, 2}]},
   {"selection", PopupMenu[Dynamic[selectionA],
     {
      "NONE"
      }, Enabled -> Dynamic[x == 1]], SpanFromLeft
    },
   {"selection", PopupMenu[Dynamic[selectionB],
     {
      "SOR", "SSOR"
      }, Enabled -> Dynamic[x == 2]], SpanFromLeft
    }
   }]
 ]

我的问题是：有没有办法在 Mathematica 中执行上述操作？我用的是8.04。

最好的解决方案是通过动态设置菜单本身的项目列表（或者整个菜单是动态的），所以我可以告诉它在 X=1 时使用 listA 或在 X=2 时使用 listB 等。但我不知道如何做到这一点，也不知道这是否可能。

附：这是我目前尝试的解决方案

Manipulate[selection,

 Grid[{
   {"x", SetterBar[Dynamic[x], {1, 2}]},
   {"selection", PopupMenu[Dynamic[selection],
     {
      Dynamic[If[x == 1, listA, listB]]
      }
     ]
    }
   }
  ],
 Initialization :>
  (
   listA = {"A", "B"};
   listB = {"C", "D"};
   )
 ]

，但效果还不是很好。会坚持下去......

谢谢

更新：

看看下面的西蒙解决方案给了我更多启发，所以这就是我到目前为止所拥有的：

Manipulate[selection,

 Grid[{
   {"x", SetterBar[Dynamic[x], {1, 2}]},
   {"selection",

    Dynamic[If[x == 1,
      (
       selection = "A";
       PopupMenu[Dynamic[selection], {"A", "B"}]
       ),
      (
       selection = "C";
       PopupMenu[Dynamic[selection], {"C", "D"}]
       )
      ]
     ]
    }
   }
  ]
 ]

Answer 1

这是您正在寻找的类型吗？

Manipulate[
 Switch[x,
        1, If[selection =!= None, selection = None],
        2, If[selection === None, selection = "SOR"]];
 selection,
 {x, {1, 2}, ControlType -> SetterBar},
 {{selection, None}, Switch[x, 1, {None}, 2, {"SOR", "SSOR"}, _, {"huh"}], 
  ControlType -> PopupMenu}]

请注意顶部的开关，当x更改时，它控制选择的默认值。

---

编辑：

按照您将菜单逻辑本地化到控件 Grid 的请求并窃取 Heike 的默认机制，这里有一个新版本：

Manipulate[selection,
 Grid[With[{menu = {{None}, {"A", "B"}, {"emu", "num"}}},
   {{"Which menu?", SetterBar[Dynamic[x], Range[Length[menu]]]},
    {"Menu selection:", Dynamic[
      If[MemberQ[menu[[x]], selection], selection = menu[[x, 1]]];
      PopupMenu[Dynamic[selection], menu[[x]]]]}}]],
 {{selection, None}, None}, {{x, 1}, None}]

请注意，menu 列表不需要使用 With 语句进行本地化 - 它可以在代码中的其他位置进行设置。

Answer 2

该解决方案类似于西蒙的答案，但它没有明确使用列表的数量，因此它应该适用于任意数量的列表

choices = {{"a", "b", "c"}, {None}, {"e", "f"}};

Manipulate[
 If[Not[MemberQ[x, selection]], selection = x[[1]]];
 selection,
 {{x, choices[[1]]}, MapIndexed[# -> #2[[1]] &, choices], SetterBar}, 
 {selection, x, ControlType -> PopupMenu}]