Antlr 语法中的赋值表达式

Question

我正在尝试扩展 Tiny Language 的语法< /a> 将赋值视为表达式。 是有效的

a = b = 1; // -> a = (b = 1)
a = 2 * (b = 1); // contrived but valid
a = 1 = 2; // invalid

因此，编写赋值与其他运算符在两个方面有所不同 。它是右关联的（没什么大不了的），它的左侧必须是一个变量。所以我像这样改变了语法

statement: assignmentExpr | functionCall ...;

assignmentExpr: Identifier indexes? '=' expression;

expression: assignmentExpr | condExpr;

它不起作用，因为它包含一个非 LL(*) 决策。我也尝试过这个变体：

assignmentExpr: Identifier indexes? '=' (expression | condExpr);

但我得到了同样的错误。 感兴趣

• 我对这个特定问题
• 给定一个非 LL(*) 决策的语法，如何找到导致问题的两条路径
• 如何修复它

Answer 1

我认为你可以像这样改变你的语法来实现相同的目的，而不使用句法谓词：

statement: Expr ';' | functionCall ';'...;

Expr: Identifier indexes? '=' Expr  |  condExpr ;

condExpr: .... and so on;

我改变了巴特的例子，考虑到这个想法：

grammar TL;

options {
  output=AST;
}

tokens {
  ROOT;
}

parse
  :  stat+ EOF -> ^(ROOT stat+)
  ;

stat
  :  expr ';' 
  ;

expr
  : Id Assign expr -> ^(Assign Id expr)

  | add
  ;

add
  :  mult (('+' | '-')^ mult)*
  ;

mult
  :  atom (('*' | '/')^ atom)*
  ;

atom
  :  Id
  |  Num
  |  '('! expr ')' !
  ;

Assign  :   '=' ;
Comment : '//' ~('\r' | '\n')* {skip();};
Id      : 'a'..'z'+;
Num     : '0'..'9'+;
Space   : (' ' | '\t' | '\r' | '\n')+ {skip();};

对于输入：

a=b=4;
a = 2 * (b = 1);

你得到以下解析树：

Answer 2

这里的关键是，您需要向解析器“保证”表达式内部存在满足该表达式的内容。这可以使用语法谓词（add 和 mult 规则中的 ( ... )=> 部分）来完成。

一个快速演示：

grammar TL;

options {
  output=AST;
}

tokens {
  ROOT;
  ASSIGN;
}

parse
  :  stat* EOF -> ^(ROOT stat+)
  ;

stat
  :  expr ';' -> expr
  ;

expr
  :  add
  ;

add
  :  mult ((('+' | '-') mult)=> ('+' | '-')^ mult)*
  ;

mult
  :  atom ((('*' | '/') atom)=> ('*' | '/')^ atom)*
  ;

atom
  :  (Id -> Id) ('=' expr -> ^(ASSIGN Id expr))?
  |  Num
  |  '(' expr ')' -> expr
  ;

Comment : '//' ~('\r' | '\n')* {skip();};
Id      : 'a'..'z'+;
Num     : '0'..'9'+;
Space   : (' ' | '\t' | '\r' | '\n')+ {skip();};

它将把输入解析

a = b = 1;       // -> a = (b = 1)
a = 2 * (b = 1); // contrived but valid

为以下 AST：