如何在 Perl 中发出并行 HTTP 请求，并按顺序接收它们？

Question

使用 Perl，我正在寻找一种简单的方法来并行执行少量 HTTP 请求，在这种方法中，我按照完成后发送的顺序返回响应，例如：

my ($google, $perl) = foobar(GET => 'http://www.google.com/',
                             GET => 'http://www.perl.org/');

是否有一个我应该查看的模块？

我知道我可以手工记账，但是在能够使用 jQuery 的 when 方法，我希望有一个使用 Perl 的简单解决方案。

感谢您的帮助。

Answer 1

use threads;
use LWP::UserAgent qw( );

my $ua = LWP::UserAgent->new();
my @threads;
for my $url ('http://www.google.com/', 'http://www.perl.org/') {
   push @threads, async { $ua->get($url) };
}

for my $thread (@threads) {
   my $response = $thread->join;
   ...
}

最好的部分是父级不需要等待所有请求完成。一旦正确的请求完成，父进程就会解除阻塞来处理它。

---

如果您使用 Parallel::ForkManager 或其他您无法等待特定子项的东西，您可以使用以下代码对结果进行排序：

for my $id (0..$#urls) {
   create_task($id, $urls[$id]);
}

my %responses;
for my $id (0..$#urls) {
   if (!exists($responses{$id})) {
      my ($id, $response) = wait_for_a_child_to_complete();
      $responses{$id} = $response;
      redo;
   }

   my $response = delete($responses{$id});
   ...
}

Answer 2

我是 Mojo 的粉丝！
来自 Mojo::UserAgent 文档：

use Mojo;
use Mojo::UserAgent;
# Parallel requests
my $ua = Mojo::UserAgent->new;
$ua->max_redirects(5);
my $delay = Mojo::IOLoop->delay;
for my $url ('http://www.google.com/', 'http://www.perl.org/') {
  $delay->begin;
  $ua->get($url => sub {
    my ($ua, $tx) = @_;
    $delay->end($tx->res->dom);
  });
}
my @responses = $delay->wait;
print join "\n", @responses

享受吧！

编辑

顺便说一句。您不必在最后处理响应，您可以在以下时间之间进行处理：

# ...
$ua->get($url => sub {
    my ($ua, $tx) = @_;
    $delay->end(1);
    # process $tx->res here
});
# ...
$delay->wait;