prolog 搜索列表

Question

我正在尝试比较这些列表。给定函数(List1，List2)并且List1具有长度N并且List 2具有长度M并且N＞M。

我想检查 List2 的任何排列是否恰好是 List1 的前 M 个字符。

例如，

predicate([a,c,b,d,e],[a,b,c,d]).

应该为真，也

predicate([a,c,b,e,d],[a,b,c,d]).

应该为假。

谢谢。

Answer 1

在描述列表之间的关系时，DCG 在这种情况下很方便：

perm_prefix(Ls1, Ls2) :- phrase(perm(Ls2), Ls1, _).

perm([])  --> [].
perm(Ls0) --> [L], { select(L, Ls0, Ls1) }, perm(Ls1).

示例案例：

?- perm_prefix([a,c,b,d,e],[a,b,c,d]).
true

?- perm_prefix([a,c,b,e,d],[a,b,c,d]).
false.

Answer 2

使用 permutation/2 和 prefix/2 谓词，您可以编写如下内容：

has_prefix_perm(List1, List2) :-
    permutation(List2, Permutation),
    prefix(Permutation, List1),
    !.

作为旁注并引用 swi-prolog 手册 :

请注意，长度为 N 的列表有 N！即使对于相当短的列表（10！= 3,628,800），排列和无界排列生成也变得非常昂贵。

因此，我会注意不要使用太长的第二个列表来调用 has_prefix_perm/2 ，特别是如果它恰好不是前缀模排列，因为所有情况都将被测试。

另一种方法是测试 List1 项目是否是 List2 的成员，直到 List2 为空，这样您就知道存在排列：

has_prefix_perm(_, []) :- !.
has_prefix_perm([Head1|List1], List2) :-
    once(select(Head1, List2, Rest)),
    has_prefix_perm(List1, Rest).

像这样写，我不会在非地面列表上使用它，但看到您的OP我没有进一步搜索...

另一种方法是检查 List1 减少到 List2 的长度是否是 List2 的排列：

has_prefix_perm(List1, List2) :-
    length(List2, L),
    length(LittleL1, L),
    append(LittleL1, _, List1),
    permutation(LittleL1, List2),
    !.

另一种方法是...我想有很多方法可以做到这一点，只需选择一个不是的方法可怕的复杂性和适合性你的风格！ :)

我个人会选择最后一个。

Answer 3

这是另一个 DCG 解决方案。

perm(Xs,Ys) :- phrase(perm(Xs),[],Ys).

perm([])-->[].
perm([X|Xs])-->perm(Xs),ins(X).

ins(X),[X]-->[].
ins(X),[Y]-->[Y],ins(X).

出处：Prolog 时刻，展示 0