如何确定变量的范围，以便其可用于同一 CFC（CFWheels 插件）中的其他函数？

Question

我想添加一个可由插件中的所有函数访问的变量，但出现变量未定义错误。这是我的插件：

component
    mixin="Controller"
{
    public any function init() {
        this.version = "1.0";
        return this;
    }

    public void function rememberMe(string secretKey="rm_#application.applicationName#") {
        this.secretKey = arguments.secretKey;
    }

    public void function setCookie(required string identifier) {
        // Create a cookie with the identifier and encrypt it using this.secretKey
        // this.secretKey is not available, though, and an error is thrown
        writeDump(this.secretKey); abort;
    }
}

我从 Sessions.cfc 控制器调用该插件：

component
    extends="Controller"
{
    public void function init() {
        // Call the plugin and provide a secret key
        rememberMe("mySecretKey");
    }

    public void function remember() {
            // Call the plugin function that creates a cookie / I snipped some code
            setCookie(user.id);
        }
}

1. 当我在插件内转储 this.secretKey 时，出现变量未定义错误。该错误告诉我 this.secretKey 在 Sessions.cfc 控制器中不可用。但我不是从 Sessions.cfc 转储，而是从插件的 CFC 转储，如您所见。为什么？

2. 如何在我的插件中设置 this.secretKey 的范围，以便可以通过 setCookie() 访问它？到目前为止，无论我在函数、伪构造函数还是 init() 中添加定义，variables 和 this 都失败了。为了更好地衡量，我添加了 variables.wheels.class.rememberME，但没有效果。

这是错误：

Component [controllers.Sessions] has no acessible Member with name [secretKey]

Answer 1

在 生产 模式下，您在 init() 中所做的操作将不起作用。控制器的 init() 仅在对该控制器的第一个请求时运行，因为此后它会被缓存。

因此，this.secretKey 将在该控制器第一次运行时设置，但不会在后续运行中设置。

您有几个选项可以完成这项工作...

I. 使用伪构造函数，它会在每个控制器请求上运行：

component
    extends="Controller"
{
    // This is run on every controller request
    rememberMe("mySecretKey");

    // No longer in `init()`
    public void function init() {}

    public void function remember() {
        // Call the plugin function that creates a cookie / I snipped some code
        setCookie(user.id);
    }
}

II. 使用伪构造函数。使用 before 过滤器来调用每个请求：

component
    extends="Controller"
{
    // No longer in `init()`
    public void function init() {
        filters(through="$rememberMe");
    }

    public void function remember() {
        // Call the plugin function that creates a cookie / I snipped some code
        setCookie(user.id);
    }

    // This is run on every request
    private function $rememberMe() {
        rememberMe("mySecretKey");
    }
}

III.将密钥存储在持久作用域中，以便仅从控制器的 init() 调用一次即可。

component
    mixin="Controller"
{
    public any function init() {
        this.version = "1.0";
        return this;
    }

    public void function rememberMe(string secretKey="rm_#application.applicationName#") {
        application.secretKey = arguments.secretKey;
    }

    public void function setCookie(required string identifier) {
        // This should now work
        writeDump(var=application.secretKey, abort=true);
    }
}