如何在一行上打印某些起始行和终止行之间的所有内容？

Question

while(<FILE>)
{
    chomp $_;
    $line[$i]=$_;
    ++$i;
}

for($j=0;$j<$i;++$j)
{
    if($line[$j]=~/Syn_Name/)
    {
        do
        {
            print OUT $line[$j],"\n";
            ++$j;
        }
        until($line[$j]=~/^\s*$/)
    }
}

这是我的代码，我试图打印 Syn_Name 和空行之间的数据。 我的代码提取了我需要的块。 但块之间的数据是逐行打印的。我希望每个块的数据打印在一行上。

Answer 1

简化您的代码。使用触发器操作符来控制打印。请注意，打印最后一行不会添加换行符（除非该行包含多个换行符）。最好的情况是，它打印空字符串。最坏的情况是，它会打印空格。

您不需要线条的转换数组，可以使用 while 循环。如果您无论如何都想存储这些行，我添加了一条注释行，说明了如何最好地完成此操作。

#chomp(my @line = <FILE>);
while (<FILE>) {
    chomp;
    if(/Syn_Name/ .. /^\s*$/) {
        print OUT;
        print "\n" if /^\s*$/;
    }
}

Answer 2

目录

• Idiomatic Perl
• 让错误更容易修复
  • 有关常见编程错误的警告
  • 变量名一致时才执行
  • 养成这个习惯将为您节省大量时间
• Perl 的范围运算
• 符 工作演示
  • 立即打印切碎的行
  • 用空格连接行
  • 还有一种极端情况

---

Idiomatic Perl

您似乎有 C 系列语言的背景。这很好，因为它可以完成工作，但您可以让 Perl 为您处理机器，即

• < code>chomp 默认为 $_ （对于许多其他 Perl 运算符也是如此）
• push 将一个元素添加到数组末尾

以简化您的第一个循环：

while (<FILE>)
{
    chomp;
    push @line, $_;
}

现在您无需更新 $i跟踪您已经添加到数组中的行数。

在第二个循环中，不使用 C 样式 for 循环，而是使用 foreach 循环：

foreach 循环迭代普通列表值，并将变量 VAR 依次设置为列表的每个元素......

foreach 关键字实际上是 for 关键字的同义词，因此您可以使用 foreach 来提高可读性，或使用 for 为简洁起见。 （或者因为 Bourne shell 比 csh 更熟悉，所以编写 for 会更自然。）如果省略 VAR，则 $_设置为每个值。




这样，Perl 就会为您处理簿记工作。

for (@line)
{
    # $_ is the current element of @line
    ...
}

使错误更容易修复

有时 Perl 可能太包容了。假设在第二个循环中您犯了一个简单的印刷错误：

for (@lines)

运行您的程序现在根本不会产生任何输出，即使输入包含 Syn_Name 块。

人们可以查看代码并发现您可能打算处理刚刚创建的数组并错误地将数组名称复数化。 Perl 急于提供帮助，创建了一个新的空 @lines 数组，这使得您的 foreach 循环无事可做。

您可以删除数组名称末尾的虚假s，但程序仍然不产生任何输出！例如，您可能有未处理的输入组合，无法打开 OUT 文件句柄。

Perl 有一些简单的方法可以让您避免因处理无声故障而遭受这些（以及更多！）的挫败感。

有关常见编程错误的警告

您可以打开大量警告列表来帮助诊断常见编程问题。通过我想象的代码的错误版本，Perl 可以告诉您

Name "main::lines" used only once: possible typo at ./synname line 16.

，并且在修复数组名称中的拼写错误后

print() on unopened filehandle OUT at ./synname line 20, <FILE> line 8.
print() on unopened filehandle OUT at ./synname line 20, <FILE> line 8.
print() on unopened filehandle OUT at ./synname line 20, <FILE> line 8.
print() on unopened filehandle OUT at ./synname line 20, <FILE> line 8.
print() on unopened filehandle OUT at ./synname line 20, <FILE> line 8.

，您会立即看到有价值的信息，这些信息可能很难或至少是单调乏味地独立发现：

1. 变量名称不一致，并且
2. 程序正在尝试产生输出，但需要更多的管道。

除非变量名一致，否则不要执行

请注意，即使存在上述潜在问题，Perl 仍会尝试执行。对于某些类型的问题（例如变量命名不一致），您可能希望 Perl 不执行您的程序，而是停下来让您先修复它。你可以告诉 Perl 严格对待变量：

如果您访问未通过 our 或 use vars 声明、通过 my 本地化的变量，则会生成编译时错误，或者不完全合格。

权衡是您必须明确哪些变量您打算成为程序的一部分，而不是让它们在第一次使用时方便地发挥作用。在第一个循环之前，您需要声明

my @line;

表达您的意图。然后，由于错误地复数数组名称的错误，Perl 失败，

Global symbol "@lines" requires explicit package name at ./synname line 16.
Execution of ./synname aborted due to compilation errors.

并且您确切地知道哪一行包含错误。

养成这个习惯会为你节省很多时间。

我几乎开始编写每一个重要的 Perl 程序。

#! /usr/bin/env perl

use strict;
use warnings;

第一个是 shebang 行，就 Perl 而言是一个普通的注释。 use 行启用 strict 编译指示和 警告 编译指示。

不想成为一个严格僵尸，如马克Dominus 斥责，我会指出 use strict; 如上所述，不带任何选项使得 Perl 严格处理三个容易出错的区域：

1. 严格变量，如上所述；
2. 严格引用，不允许使用符号引用； 严格的子程序
3. ，要求程序员在引用子程序时更加小心。

这是一个非常有用的默认值。有关更多详细信息，请参阅strict pragma 文档。

Perl 的范围运算符

perlop 文档 描述了 ..，Perl 的范围运算符，可以帮助您大大简化第二个循环中的逻辑：

在标量上下文中，.. 返回一个布尔值。该运算符是双稳态的，就像触发器一样，并模拟 sed、awk 和各种编辑器的行范围（逗号）运算符。每个 .. 运算符都维护自己的布尔状态，即使在调用包含它的子例程时也是如此。只要它的左操作数为假，它就是假的。一旦左操作数为真，范围运算符将保持为真，直到右操作数为真，之后范围运算符再次变为假。在下次计算范围运算符之前它不会变为 false。

在你的问题中，你写道你想要“Syn_Name 和空行之间的数据”，在 Perl 中拼写

/Syn_Name/ .. /^\s*$/

为在你的情况下，你还想在范围末尾做一些特殊的事情，并且 .. 也提供了这种情况，同上。

范围中的最终序列号附加了字符串“E0”，这不会影响其数值，但如果您想排除端点，则可以为您提供搜索内容.

分配从 .. 返回的值（我通常对名为 $inside 或 $is_inside 的标量执行此操作）允许您检查是否“ re 在末尾，例如，

my $is_inside = /Syn_Name/ .. /^\s*$/;
if ($is_inside =~ /E0$/) {
    ...
}

以这种方式编写还可以避免重复终止条件的代码（.. 的右侧操作数）。这样，如果您需要更改逻辑，只需在一处更改即可。当您必须记住时，有时您会忘记并产生错误。

工作演示

请参阅下面的代码，您可以复制并粘贴以获得工作程序。出于演示目的，它们从内置 DATA 文件句柄读取输入并将输出写入 STDOUT。以这种方式编写意味着您可以将我的代码转移到您的代码中，而无需进行很少的修改或无需修改。

立即打印 chomped 行

正如您的问题中所定义的，不需要一个循环来收集临时数组中的行，然后另一个循环来处理该数组。考虑以下代码，

#! /usr/bin/env perl

use strict;
use warnings;

# for demo only
*FILE = *DATA;
*OUT = *STDOUT;

while (<FILE>)
{
    chomp;
    if (my $is_inside = /Syn_Name/ .. /^\s*$/) {
        my $is_last = $is_inside =~ /E0$/;
        print OUT $_, $is_last ? "\n" : ();
    }
}

__DATA__
ERROR IF PRESENT IN OUTPUT!

Syn_Name
foo
bar
baz

ERROR IF PRESENT IN OUTPUT!

其输出为“

Syn_Namefoobarbaz

我们总是打印当前行，存储在 $_”中。当我们到达范围的末尾时，即当 $is_last 为 true 时，我们还会打印换行符。当 $is_last 为 false 时，三元运算符另一个分支中的空列表就是结果，这意味着我们仅打印 $_，不打印换行符。

用空格连接行

您没有向我们展示示例输入，所以我想知道您是否真的想将这些行连接在一起而不是 用空格连接它们。如果您想要后一种行为，则程序将变为

#! /usr/bin/env perl

use strict;
use warnings;

# for demo only
*FILE = *DATA;
*OUT = *STDOUT;

my @lines;
while (<FILE>)
{
    chomp;
    if (my $is_inside = /Syn_Name/ .. /^\s*$/) {
        push @lines, $_;
        if ($is_inside =~ /E0$/) {
            print OUT join(" ", @lines), "\n";
            @lines = ();
        }
    }
}

__DATA__
ERROR IF PRESENT IN OUTPUT!

Syn_Name
foo
bar
baz

ERROR IF PRESENT IN OUTPUT!

此代码仅在 Syn_Name 块内的那些行中累积@lines，打印该块，并在我们执行时清除@lines。看到终结者。现在的输出是

Syn_Name foo bar baz

另一种边缘情况

最后，如果我们在文件末尾看到 Syn_Name 但没有终止空行，会发生什么情况？对于您的数据来说这可能是不可能的，但如果您需要处理它，您将需要使用 Perl 的 eof 运算符。

eof FILEHANDLE
eof

如果 FILEHANDLE 的下一次读取将返回文件结尾，或者 FILEHANDLE 未打开，则返回 1 ... 不带参数的 eof 使用最后读取的文件。

因此，我们在空行或文件末尾处终止。

#! /usr/bin/env perl

use strict;
use warnings;

# for demo only
*FILE = *DATA;
*OUT = *STDOUT;

my @lines;
while (<FILE>)
{
    s/\s+$//;
    #if (my $is_inside = /Syn_Name/ .. /^\s*$/) {
    if (my $is_inside = /Syn_Name/ .. /^\s*$/ || eof) {
        push @lines, $_;
        if ($is_inside =~ /E0$/) {
            print OUT join(" ", @lines), "\n";
            @lines = ();
        }
    }
}

__DATA__
ERROR IF PRESENT IN OUTPUT!
Syn_Name
foo
bar

YOU CANT SEE ME!
Syn_Name
quux
potrzebie

输出：

Syn_Name foo bar 
Syn_Name quux potrzebie

这里代码删除了所有尾随的内容，而不是 chomp行尾不可见的空白。即使输入有点马虎，这也将确保连接线之间的间距是均匀的。

如果没有 eof 检查，程序不会打印后一行，您可以通过注释掉活动条件并取消注释另一行来看到这一点。

Answer 3

另一个简化版本：

foreach (grep {chomp; /Syn_Name/ .. /^\s*$/ } <FILE>) {
    print OUT;
    print OUT "\n" if /^\s*$/;
}