Perl 使用 coderef 作为子例程的参数

Question

我有以下子例程：

sub my_sub {
    my $coderef = shift;    
    $coderef->();
}


sub coderef {
    my $a = shift;
    my $b = shift;

    print $a+$b;
}

并且想要以这种方式调用 my_sub(\coderef($a,$b)) 即我想提供代码引用的参数并在my_sub 函数。在perl中可以做这样的事情吗？

Answer 1

如果从表面上看这些潜艇，那么 my_sub 不会做任何事情。

这里发生了两件事：

1. 定义 coderef

   my $adder = sub { my ( $first, $second ) = @_; $第一 + $第二 };
   
   # 添加前两个参数
   

2. 使用必要的参数执行它

   print $adder->(2,3); #'5'
   

---

假设 my_sub 是某种函子，并将 coderef 作为其第一个参数传递：

sub functor {
    my $coderef = shift;  # Pull of first argument
    $coderef->( @_ );     # Rest of @_ are coderef arguments
                          # Or simply : sub functor { +shift->( @_ ) }
}

# Usage:

print functor ( $adder, 2, 3 );  # '5'

Answer 2

如果我正确理解您的问题，您需要将对 coderef 子例程的调用包装在另一个匿名子例程中，如下所示：

my_sub(sub { coderef(2, 3); }); # replace 2, 3 with whatever arguments 

Answer 3

这是你想要的吗？

use warnings;
use strict;

&my_sub( \&coderef );

sub my_sub {
    my $coderef = shift;
    $coderef->(2, 3);
}

sub coderef {
    my $a= shift;
    my $b = shift;

    print $a+$b;
}

Answer 4

使用匿名子例程。

my $coderef = sub {
    my ($aa, $bb) = @_;
    print $aa + $bb;
};

sub my_sub {
    my ($c_ref, @params) = @_;
    $c_ref->(@params);
}

my_sub($coderef, 2, 3);

Answer 5

另一个想法。也许闭包可以解决您的问题？如果您将 coderef 编写为工厂，那么您可以像这样编写代码：

use strict;
use warnings;

my_sub(coderef(2,3));

sub my_sub {
  my $coderef = shift;    
  $coderef->();
}

sub coderef {
    my $a = shift;
    my $b = shift;

    return sub { print $a + $b };
}

OUTPUT

5