Cygwin 从一个批处理文件运行脚本？

Question

我知道 Cygwin 安装时有一个批处理文件用于在 Windows 中启动它。但是，如果我想在不启动 Cygwin 并执行“./script”的情况下运行脚本，

如何创建批处理文件来执行此操作？

就像...只需一个批处理文件，单击该批处理文件即可打开 Cygwin 并运行 shell 脚本。

Answer 1

要运行“foo.bsh”，请创建一个包含以下内容的批处理文件并运行它：

    set PATH=C:\cygwin\bin;%PATH%
    c:\cygwin\bin\bash.exe c:\path\to\foo.bsh

“C:\cygwin\bin”部分可能会有所不同，具体取决于您选择的 cygwin 安装位置。

Answer 2

你可以尝试像这样从 CMD 蹦床到 BASH （或任何 sh 变体）：

    : <<TRAMPOLINE
    @echo off
    bash -c "exit 0" || (echo.No bash found in PATH! & exit /b 1)
    bash "%~f0" "%*" 
    goto :EOF 
    TRAMPOLINE
    #####################
    #!/bin/bash  -- it's traditional!
    echo "Hello from $SHELL"

Answer 3

我想扩展 Austin Hastings 给出的答案，以允许它在路径中没有 Cygwin 的情况下工作，并在使用 bat 文件设置的目录中工作（因此，甚至使用具有不同“开始于”路径的快捷方式） 。更改是包含 bash 的完整路径，使用选项 -l 使 bash 设置正确的路径和环境，并将当前目录传递给 bash 作为弹出的第一个参数（使用 >转移）。记住在文件中使用 Unix 换行符，否则你会得到很多错误。也使用 UTF8 而不是 ANSI。

: <<TRAMPOLINE
@echo off
C:\cygwin\bin\bash -c "exit 0" || (echo.No bash found in PATH! & exit /b 1)
setlocal EnableDelayedExpansion
for %%i in (%*) do set _args= !_args! "%%~i"
C:\cygwin\bin\bash -l "%~f0" "%CD%" %_args%
goto :EOF 
TRAMPOLINE
#####################
#!/bin/bash  -- it's traditional!
cd "$1"
shift
echo Working from $PWD

编辑：修复了蹦床代码以将参数正确传递给 bash。 BAT 文件没有相当于“$@”的 bash，并且会创建一个处理每个参数的循环，然后将其传递给 bash.exe。现在可以正确处理带空格的参数。

Answer 4

如果您还想在薄荷窗口中打开脚本，这（基于@galmok的答案）就可以了。

: <<TRAMPOLINE
@echo off
C:\Users\user\Downloads\cyg-packages\bin\bash -c "exit 0" || (echo.No bash found in PATH! & exit /b 1)
setlocal EnableDelayedExpansion
for %%i in (%*) do set _args= !_args! "%%~i"
C:\Users\user\Downloads\cyg-packages\bin\mintty.exe -i /Cygwin-Terminal.ico C:\Users\user\Downloads\cyg-packages\bin\bash -l "%~f0" "%CD%" %_args%
goto :EOF 
TRAMPOLINE
#####################
#!/bin/bash  -- it's traditional!
cd "$1"
shift
echo Working from $PWD
vim "$@"

注意：我的用例是需要从 Visual Studio 打开终端 vim，这就是最后调用 vim 的原因。批处理文件随后将退出。

Answer 5

什么样的 shell 脚本？重击？如果您需要运行 bash 脚本，只需通过快捷方式使用 bash.exe 运行它即可。目标类似于：

C:\cygwin\bin\bash.exe foo.bsh

bash.exe 的路径将取决于 cygwin 的安装位置。 （如果 bin 目录位于路径环境变量中，则根本不需要路径。）

如果需要，您可以在批处理脚本中执行相同的操作。命令行与上面的“目标”相同。

---

根据注释进行编辑（仍然假设 bash）：

好的，所以在批处理脚本 (.bat) 中只需键入：

bash.exe script.txt

您可能需要添加“bash.exe”的路径。如果您不确定“bash.exe”在哪里，请打开您在问题中提到的“Cygwin.bat”文件。它应该在 chdir 命令中包含路径。 （注意：Cygwin.bat 只是以交互模式运行 bash.exe。它并没有真正运行名为“cygwin”的任何内容。）

如果“script.txt”不在同一目录中，您还需要添加“script.txt”的路径作为您的批处理脚本。

同样，这也可以在快捷方式而不是批处理脚本中工作。

Answer 6

要从任何 .bat 文件运行“your_bash_file”，请将以下行写入 .bat：

git-bash.exe (path_to_your_bash_file>)

PS Windows Git 必须安装