F# 测量单位：从弧度到速度（米/秒）

Question

假设我已经定义了一个用于处理 3 维向量和测量单位的 F# 模块：

[<Measure>]
type m
[<Measure>]
type s
[<Measure>]
type v = m/s
[<Measure>]
type rad

type Vector3<[<Measure>] 'a> =
    {
    X : float<'a>
    Y : float<'a>
    Z : float<'a>
    }

在某处我有一个以弧度表示的角度：

let angle:float32<rad> = 0.5f<rad>

现在我必须声明一个 Vector3（速度），使用该角度来计算其分量。我尝试了类似的方法：

let velocity : Vector3<m/s> = { X = Math.Cos(angle);Y = Math.Sin(angle);Z = 0.0<m/s>} //don't compile

上面的代码无法编译，因为 Vector3 需要 X 和 Y 中的值，但 Sin 返回一个浮点数。

我该如何解决这个问题？如果可能的话，我想在测量单位之间执行转换，而不是强制转换，这样编译器就可以保证我在将角度转换为速度时做正确的事情。

有什么建议吗？

Answer 1

这里有几个问题：
cos 需要一个无单位的值，因此您必须去掉 angle 的单位；鉴于速度需要 float 而不是 float32，您不妨直接转换为 float （这会删除单位）。

然后，您需要重新安装这些装置。在度量单位的第一个版本中，您可以通过简单地乘以适当度量的 1 来完成此操作。现在有 LanguagePrimitives.FloatWithMeasure，它更正确，但稍微更详细。

let velocity =
 {
     X = angle |> float |> cos |> LanguagePrimitives.FloatWithMeasure<m/s> ;
     Y = angle |> float |> sin |> LanguagePrimitives.FloatWithMeasure<m/s> ;
     Z = 0.0<m/s> ;
 }

除此之外，10 弧度是一个有趣的角度...

（请注意，cos 和 sin 是内置的）

Answer 2

好的，这是另一种方法，演示如何结合标量速度和 2d 方向来真正利用您的单位：

let vvector (velocity:float<'u>) (xydirection:float<rad>) =
    { 
        X = cos (float xydirection) * velocity;
        Y = sin (float xydirection) * velocity;
        Z = 0.<_>
    }

这给出了：

> vvector 15.3<m/s> angle<rad>;;
val it : Vector3<m/s> = {X = 13.4270132;
                         Y = 7.335210741;
                         Z = 0.0;}

您可以通过向 Vector3 类型添加一个运算符来更进一步：

static member (*) (v1: Vector3<'u>, n: float<'v>) =
    { X = v1.X * n; Y = v1.Y * n; Z = v1.Z * n }

这意味着您然后可以这样做：

let vvector2 (velocity:float<'u>) (xydirection:float<rad>) =
    { X = cos(float xydirection); Y = sin(float xydirection); Z = 0. } * velocity

显然，你仍然没有真正在其中“使用”弧度，但这是预期的，无论如何弧度都是“非”单位。您可以使用它们的一种方法是如果您希望能够管理弧度和度数。您可以在 Vector3 上添加另外两个静态成员：

static member ofAngle (ang:float<rad>) = 
    { X = cos(float ang); Y = sin(float ang); Z = 0.0 }
static member ofAngle (ang:float<degree>) = 
    Vector3<'u>.ofAngle(ang * 2.<rad> * System.Math.PI / 360.<degree>)

这看起来不错，但不幸的是它无法编译，因为一旦元组、函数和/或，方法“ofAngle”与此类型中的另一个方法具有相同的名称和签名测量单位被删除。您可以查看这个问题了解更多详情

Answer 3

如果可能的话我想在度量之间执行转换
单位，而不是强制转换，这样编译器就可以
保证我在变换角度的同时做正确的事
变成速度。

你要求的是矛盾的事情。测量单位通过使用类型推断来强制程序中的单位来帮助保证程序的正确性，因此必须显式地进行转换。

正如@Benjol 所说，您必须在有维数据和无量纲数据之间进行转换。下面的代码是一个非正式版本，我通过乘以其单位值将 float 转换为 float：

let angle:float32<rad> = 0.5f<rad>

let velocity = {
                X = sin (float angle) * 1.0<m/s> ; 
                Y = cos (float angle) * 1.0<_> ; 
                Z = 0.0<_>
               } 

请注意，您只需为 X 指定单位，其他单位是根据 Vector3 的类型声明推断的。