在经典 ASP 中，如何获取动态数组内部是否有元素？

Question

如果我声明一个像这样的动态大小的数组

Dim myArray()

，那么如果该数组为空或包含元素，我如何进入代码？

我尝试使用 IsArray(myArray) 函数，该函数始终为 True，

否则如果我尝试使用 UBound(myArray) 函数，则会收到错误。

有什么想法吗？预先感谢，

马克斯

Answer 1

声明数组后，您必须初始化它：

Dim myArray()
ReDim myArray(-1)

然后这样的代码将始终有效：

If UBound(myArray)<0 Then
    'array is empty....
Else  
    'array not empty....
End If

编辑：由于您无法初始化数组，这里有更长的方法来检查它是否为空：

Dim x, myCount
myCount = 0
If IsArray(myArray) Then
    For Each x In myArray
        myCount = myCount + 1
    Next
End If
If myCount=0 Then
    'array is empty....
Else  
    'array not empty....
End If

Answer 2

首先是一些注释。

1. 在 VBScript 中使用 Dim A() 不太实用，最好使用 ReDim
A（n）。
2. 例如，ReDim A(-1) 也是空数组（无元素），但已初始化。

程序员最好的交流方式是通过示例......

Dim a(), b(0), c
c = Array(a, b)
ReDim d(-1)

WScript.Echo "Testing HasBound:"
WScript.Echo "a = " & HasBound(a) & ",", _
             "b = " & HasBound(b) & ",", _
             "c = " & HasBound(c) & ",", _
             "d = " & HasBound(d)
WScript.Echo "Testing HasItems:"
WScript.Echo "a = " & HasItems(a) & ",", _
             "b = " & HasItems(b) & ",", _
             "c = " & HasItems(c) & ",", _
             "d = " & HasItems(d)

'> Testing HasBound:
'> a = False, b = True, c = True, d = True
'> Testing HasItems:
'> a = False, b = True, c = True, d = False

Function HasBound(anyArray)
    On Error Resume Next
    HasBound = UBound(anyArray)
    HasBound = (0 = Err)
    On Error Goto 0
End Function

Function HasItems(anyArray)
    For Each HasItems In anyArray
        HasItems = 1
        Exit For
    Next
    HasItems = (HasItems > 0)
End Function

如您所见，两个函数具有不同的目的。差异在数组 d 上可见，它“有边界”但“有非项目”。

Answer 3

我找到了一个解决方案，我编写了一个特定的函数来检查数组是否为空；该函数不会检查它内部是否有元素，但仅检查该数组是否被声明为动态的，没有维度且没有元素。

Dim dynamic_array()                         'array without a dimension
Dim empty_array(0)                          'array with a dimension but without an element inside
Dim full_array(0) : full_array(0) = "max"   'array with a dimension and with an element inside


Function IsNullArray(input_array)
    On Error Resume Next
    Dim is_null : is_null = UBound(input_array)
    If Err.Number = 0 Then
        is_null = False
    Else
        is_null = True
    End If
    IsNullArray = is_null
End Function


If IsNullArray(dynamic_array) Then

    Response.Write("<p>dynamic array not 'ReDimed'</p>")

End If

If Not IsNullArray(empty_array) Then

    Response.Write("<p>" & UBound(empty_array) & "</p>") 'return the last index  of the array

End If

If Not IsNullArray(full_array) Then

    Response.Write("<p>" & full_array(UBound(full_array)) & "</p>") 'return the value of the last element of the array

End If

Answer 4

我现在能想到的一件事是：

On Error resume next
if UBound(myArray) < 0 then response.write "Empty array" end if

编辑：麦克斯的评论

Answer 5

我总是检查 UBound = 0 并且第一个元素也为空：

If UBound(myArray) = 0 Then
    if myArray(0) = "" then ''Depending on the type of the array
       ''array is empty....
    End If
End If