如何区分未传递的参数和传递错误值的参数？

Question

我试图找出在 Perl 中区分未传递参数和参数已作为 0 传递的情况的最佳方法，因为它们对我来说意味着不同的事情。

（通常我喜欢这种歧义性，但在这种情况下，我正在生成 SQL，所以我想用 NULL 替换未定义的参数，但将 0 保留为 0。）

所以这就是歧义性：

sub mysub {
  my $arg1 = shift;
  if ($arg1){
    print "arg1 could have been 0 or it could have not been passed.";
  }
}

到目前为止，这是我最好的解决方案..但我觉得有点丑。我想知道你是否能想出一种更干净的方法，或者这对你来说是否可行：

sub mysub {
  my $arg1 = (defined shift) || "NULL";
  if ($arg1 ne "NULL"){
    print "arg1 came in as a defined value.";
  }
  else {
    print "arg1 came in as an undefined value (or we were passed the string 'NULL')";
  }
}

Answer 1

以下是如何处理所有可能情况的示例：（

sub mysub {
    my ($arg1) = @_;
    if (@_ < 1) {
        print "arg1 wasn't passed at all.\n";
    } elsif (!defined $arg1) {
        print "arg1 was passed as undef.\n";
    } elsif (!$arg1) {
        print "arg1 was passed as a defined but false value (empty string or 0)\n";
    } else {
        print "arg1 is a defined, non-false value: $arg1\n";
    }
}

@_ 是函数的参数数组。此处将其与 1 进行比较，计算元素数量我故意避免使用 shift，因为它会改变 @_，这需要我们存储 @_ 的原始大小。某处。）

Answer 2

怎么样：

sub mysub {
    my ( $arg ) = @_;

    if ( @_ == 0 ) {
        print "arg did not come in at all\n";
    } elsif ( defined $arg ) {
        print "arg came in as a defined value.\n";
    } else {
        print "arg came in as an undefined value\n";
    }
}

mysub ();
mysub ( undef );
mysub ( 1 );

更新：我添加了检查是否有任何内容传入。但这仅在您需要单个参数时才有用。如果您想获取多个参数并需要区分未定义和省略的参数，请采用哈希值。

sub mysub_with_multiple_params {
    my %args_hash = @_;

    for my $expected_arg ( qw( one two ) ) {
        if ( exists $args_hash{ $expected_arg } ) {
            if ( defined $args_hash{ $expected_arg } ) {
                print "arg '$expected_arg' came in as '$args_hash{ $expected_arg }'\n";
            } else {
                print "arg '$expected_arg' came in as undefined value\n";
            }
        } else {
            print "arg '$expected_arg' did not come in at all\n";
        }
    }
}

mysub_with_multiple_params ();
mysub_with_multiple_params ( 'one' => undef, 'two' => undef );
mysub_with_multiple_params ( 'one' => 1, 'two' => 2 );

顺便说一句：如果您必须执行任何步骤来清理您的参数，请不要自己执行。看看cpan，尤其是Params::Validate

Answer 3

就我个人而言，我喜欢保留 undef 来表示 NULL - 它与 DBI 占位符/DBIx::Class/SQL::Abstract 的所有功能相匹配，以及将其设置为字符串 "NULL" 的风险 的问题是您会意外插入字符串，而不是 NULL 本身。

如果您使用的是最新版本的 Perl（5.10 或更高版本），请查看特别方便的“定义或”运算符 // 和 //=用于处理参数。

关于 SQL，如果你想生成 SQL 字符串，你可能会得到这样的结果：

sub mysub {
  my ($args) = @_;
  my @fields = qw/ field1 field2 field3 /;
  my $sql = "INSERT INTO mytable (field1,field2,field3) VALUES (" .
   join(',', map { ("'".$args->{$_}."'") // 'NULL' ) } )
    .")";
  return $sql;
}

编辑（回答有关 NULL 和 undef 的问题）：

使用带有占位符的 DBI 句柄：

my $sth = $dbh->prepare('INSERT INTO mytable (field1,field2,field3) '.
                        'VALUES (?,?,?)');

# undef will set a NULL value for field3 here:
$sth->execute( "VAL1", "VAL2", undef );

DBIx::Class

DBIx::Class - 相同的原理 - 传入一个未定义在数据库中创建 NULL 的值：

my $rs = My::Schema->resultset('MyTable');
my $obj = $rs->create({
   field1 => 'VAL1',
   field2 => 'VAL2',
   field3 => undef,    # will set a `NULL` value for field3 here
});

Answer 4

唯一确定的方法是检查 @_ 的长度以查看该槽中是否有参数。当还存在强制参数时，这可能会被视为有点复杂，但事实并非如此。这是许多对象访问器中使用的模式：

package Foo;

sub undef_or_unset {
    my ($self, @arg) = @_;

    return 'unset' unless @arg;
    my ($val) = @arg;

    return 'undef' unless defined $val;
    return 'defined';
}

package main;
use Test::More tests => 3;

my $foo = bless {} => 'Foo';

is($foo->undef_or_unset(), 'unset');
is($foo->undef_or_unset(undef), 'undef');
is($foo->undef_or_unset('bluh'), 'defined');

Answer 5

地图是你的朋友。尝试一下：

function("joe",undef); # should print "joe" and "NULL"
function("max",38);    # should print "max" and "38"
function("sue",0);     # should print "sue" and "0"   

sub function {
    my($person,$age) = map { $_ // "NULL" } @_;
    print "person: $person\n";
    print "age:    $age\n";
}

为了添加更多色彩，我喜欢使用哈希作为参数，以提高代码清晰度并消除记住参数顺序的重要性。所以重写它看起来像这样：（

function2(person=>"joe",age=>undef); # should print "joe" and "NULL"
function2(person=>"max",age=>38);    # should print "max" and "38"

sub function2 {
    my(%args) = map { $_ // "NULL" } @_;
    print "person: $args{person}\n";
    print "age:    $args{age}\n";
}

更新：正确处理 0，然后再次使用 // 运算符。）