如何在perl中分割具有多个模式的字符串？

Question

我想用多种模式分割一个字符串：

例如。

my $string= "10:10:10, 12/1/2011";

my @string = split(/firstpattern/secondpattern/thirdpattern/, $string);

foreach(@string) {
    print "$_\n";
}

我想要的输出是：

10
10
10
12
 1
2011

执行此操作的正确方法是什么？

Answer 1

在正则表达式分隔符中使用 字符类 来匹配一组可能的字符分隔符。

my $string= "10:10:10, 12/1/2011";
my @string = split /[:,\s\/]+/, $string;

foreach(@string) {
    print "$_\n";
}

说明

• 斜杠对/.../表示要匹配的正则表达式或模式。

• 一对方括号[...]表示正则表达式的字符类。

• 里面是可以匹配的可能字符集：冒号:、逗号,、任何类型的空格字符\s、和正斜杠 \/ （使用反斜杠作为转义字符）。

• 需要 + 来匹配其前面的 1 个或多个字符，在本例中是整个字符类。如果没有这个，逗号空格将被视为 2 个单独的分隔符，从而在结果中为您提供一个额外的空字符串。

Answer 2

错误的工具！

my $string = "10:10:10, 12/1/2011";
my @fields = $string =~ /([0-9]+)/g;

Answer 3

您可以按非数字进行拆分；

#!/usr/bin/perl
use strict;
use warnings;
use 5.014;

my $string= "10:10:10, 12/1/2011";
say for split /\D+/, $string;

Answer 4

my $string= "10:10:10, 12/1/2011";

my @string = split(m[(?:firstpattern|secondpattern|thirdpattern)+], $string);

my @string = split(m[(?:/| |,|:)+], $string);

print join "\n", @string;

Answer 5

回答你原来的问题：
您正在寻找|运算符：

my $string = "10:10:10, 12/1/2011";

my @string = split(/:|,\s*|\//, $string);

foreach(@string) {
    print "$_\n";
}

但是，正如其他答案所指出的那样，您通常可以通过进一步简化或概括来改进这一点。

Answer 6

如果数字是您想要的，请提取数字：

my @numbers = $string =~ /\d+/g;
say for @numbers;

不需要捕获括号，如

/g 修饰符指定全局模式匹配——即匹配
在字符串中尽可能多地出现。它的行为方式取决于
上下文。在列表上下文中，它返回子字符串的列表
与正则表达式中的任何捕获括号匹配。 如果
没有括号，它返回所有匹配的列表
字符串，就好像整个模式周围都有括号。

Answer 7

当您解析明显是日期/时间的内容时，我想知道使用 DateTime::Format::Strptime 将其解析为 DateTime 对象。