如何将 Maven 嵌入到我的应用程序中？

Question

我想将 Maven 或能够发挥所有作用的库嵌入到我的 Java 应用程序中。

要点：

• 这是我想要执行的两项任务：

  1/ 在本地存储库中发布 jar
  2/ 在私有企业存储库（Nexus）中发布 jar

• 所有必需的 jar 必须位于公共 Maven 存储库中

• jar 应该是 Maven版本无关（即不特定于 Maven 2 或 3）

如果可以的话，请提供您的回复的片段。

Answer 1

Maven 客户端使用正常的 HTTP“POST”操作将内容推送到 Nexus。如果您只想发布内容，那么您不需要下载和解决依赖关系的所有逻辑...

如果您决定需要成熟的 Maven 存储库互操作性，那么我建议模仿其他项目，例如 Groovy ，Gradle和Scala都做了，就是嵌入Apache Ivy。

我发现以下文章描述了如何将ivy添加到您的java项目中（单jar依赖项）：

http://developers-blog.org/blog/default/2010/11/08/Embed-Ivy-How-to-use-Ivy-with-Java

Groovy 示例

您的问题是具体来说如何添加对发布内容的支持。

以下代码使用 ivy 发布到 Nexus 存储库。 Groovy 使您能够使用Ivy 记录的 ANT 任务。

import groovy.xml.NamespaceBuilder
import groovy.xml.MarkupBuilder

// Methods
// =======
def generateIvyFile(String fileName) {
    def file = new File(fileName)

    file.withWriter { writer ->
        xml = new MarkupBuilder(writer)

        xml."ivy-module"(version:"2.0") {
            info(organisation:"org.dummy", module:"dummy")
            publications() {
                artifact(name:"dummy", type:"pom")
                artifact(name:"dummy", type:"jar")
            }
        }
    }

    return file
}

def generateSettingsFile(String fileName) {
    def file = new File(fileName)

    file.withWriter { writer ->
        xml = new MarkupBuilder(writer)

        xml.ivysettings() {
            settings(defaultResolver:"central")
            credentials(host:"myrepo.com" ,realm:"Sonatype Nexus Repository Manager", username:"deployment", passwd:"deployment123")
            resolvers() {
                ibiblio(name:"central", m2compatible:true)
                ibiblio(name:"myrepo", root:"http://myrepo.com/nexus", m2compatible:true)
            }
        }
    }

    return file
}

// Main program
// ============
def ant = new AntBuilder()
def ivy = NamespaceBuilder.newInstance(ant, 'antlib:org.apache.ivy.ant')

generateSettingsFile("ivysettings.xml").deleteOnExit()
generateIvyFile("ivy.xml").deleteOnExit()

ivy.resolve()
ivy.publish(resolver:"myrepo", pubrevision:"1.0", publishivy:false) {
    artifacts(pattern:"build/poms/[artifact].[ext]")
    artifacts(pattern:"build/jars/[artifact].[ext]")
}

Answer 2

以下是嵌入 Maven 2 库的示例：

• CentralRepositoryService.java
• pom.xml

而不是查找项目构建器，您可以查找 ArtifactInstaller 和 ArtifactDeployer - 您将在 maven-install-plugin 和maven-deploy-plugin。

本示例中 POST 的区别在于它将生成适当的元数据、校验和和快照转换。

Maven 3 库可能更容易嵌入并与 Maven 2 保持兼容，但是我没有任何可用的示例。

Answer 3

我还没有尝试过你想要的，但我会首先研究 Maven Embedder 项目。甚至可能是 m2e 项目，它也附带了 Maven 的嵌入式版本（并且也能够使用外部安装）。

本地发布可能涉及调用 maven-install-plugin，远程发布可能涉及使用 maven-deploy-plugin。

希望这能为您指明正确的方向。