如何禁用 Commodore 64 中的屏幕？

Question

我知道这个问题是非常具体的问题，但我知道这里有一些 c64 代码专家。所以，这是我的问题。

当我尝试使用 $d011 技巧禁用屏幕时，上/下边框也会打开。我想在不打开上/下边框的情况下做到这一点。是否可以？

Answer 1

哦，一个c64问题。好的。 :) 我的代码存档中有一个示例。您需要在屏幕的开头而不是末尾执行 $d011 技巧。

这是 ACME 源代码。

    !to "nobadlines.prg",cbm

!macro WAIT .v {
    ldy #.v
    dey
    bne *-1
}

    * = $0801
    !byte $0c, $08, $00, $00, $9e, $32, $30, $36, $31, $00, $00, $00

    * = $080d
    lda #$01
    sta $3fff
    sei
start:
    lda #$30
    cmp $d012
    bne *-3
    lda #$00
    sta $d011
    +WAIT 24
    lda #$0b
    sta $d011
    lda #$31
    cmp $d012
    bne *-3
    lda #$1b
    sta $d011
    +WAIT 8
    bit $ea
    ldx #$00
loop1:
    txa
    sta $d020
    sta $d021
    +WAIT 9
    inx
    cpx #254
    bne loop1
    asl $3fff
    bne start
    inc $3fff
    jmp start

这是应要求提供的 Kick Assembler 版本。

    * = $0801
    BasicUpstart($080d);

    * = $080d
.macro WAIT(duration) {
        ldy #duration
        dey
        bne *-1
}

        lda #$01
        sta $3fff
        sei
start:
        lda #$30
        cmp $d012
        bne *-3
        lda #$00
        sta $d011
        WAIT(24)
        lda #$0b
        sta $d011
        lda #$31
        cmp $d012
        bne *-3
        lda #$1b
        sta $d011
        WAIT(8)
        bit $ea
        ldx #$00
loop1:
        txa
        sta $d020
        sta $d021
        WAIT(9)
        inx
        cpx #254
        bne loop1
        asl $3fff
        bne start
        inc $3fff
        jmp start