什么语法将检查是否定义了包含空格的变量名？

Question

Windows 用户定义的环境变量名称可以包含除 = 之外的任何字符。

可以通过转义特殊字符来包含它们。一种更简单的方法是简单地将整个 SET 表达式括在引号内。例如：

set "A weird & "complex" variable=My value"
set A weird ^& "complex" variable=My value

上面的两个表达式给出相同的结果。变量名称是一个奇怪的& “complex”变量，值为我的值

IF DEFINED 构造用于测试变量是否已定义。引号不适用于此测试，名称中的特殊字符（包括引号）必须进行转义。

set "A&B=value"
if defined A^&B echo This works
if defined "A&B" echo This does not work

上面的转义测试工作得很好。引用的测试不起作用

但是如何测试包含空格的变量是否存在？

set "A B=value"
if defined A^ B echo this does not work!

看起来上面的方法应该有效，但事实并非如此！

我正在寻找一个不涉及使用 %AB% 或 !AB! 扩展变量的答案

Answer 1

有趣的问题（我喜欢这个语法基础问题）。

显然，您知道如何通过延迟扩展来检查它，并且 FOR 参数也有效。

@echo off
setlocal
set "AAA BBB=value"
set ""AAA BBB"="
set "AAA="
for %%a in ("AAA BBB") do if defined %%~a echo FOR: This works

setlocal EnableDelayedExpansion
set "varname=AAA BBB"
if defined !varname! echo Delayed: This works

if defined %varname% ( echo percent: Never comes here 
) ELSE ( echo percent: Never comes here ? )

if defined AAA^ BBB ( echo escape1: Never comes here
) ELSE ( echo escape1: fails )

set AAA=Hello
if defined AAA^ BBB ( 
   echo escape2: It only test for AAA the BBB will be "removed"
) ELSE ( echo escape2: fails )

set "space= "
if defined AAA!space!BBB echo inject space: This works

if defined "AAA BBB"  (echo Quote1: Never comes here 
) ELSE ( echo Quote1: Fails )

set ""AAA BBB"=value"
if defined "AAA BBB" echo Quote2: This works, it checks for "AAA BBB" with quotes

在我看来，在 escape2 示例中，解析器首先以这种方式将行拆分为标记：
<代码><如果> <定义><回声....
但在 if Defined 执行时，它会重新扫描 令牌，因此它只获取 AAA。
您不能注入像 AAA^^^ BBB 这样的第二个转义符，因为它只搜索名为 AAA^ 的变量，

如果不延迟/FOR，我看不到解决方案，因为逃离空间总是失败。

编辑：也可以用 SET
解决
ijprest的解决方案是使用SET命令来测试变量，而不需要对varname进行转义。
但它也显示了变量名称内部和末尾的空格的有趣行为。

它似乎遵循以下规则：
SET varname 搜索以 varname 开头的所有变量，但首先删除 varname 最后一个空格字符之后的所有字符，并删除所有前导空格。
所以你不能搜索以空格开头的变量（但创建这样的变量名也有点棘手）。

如果变量名括在引号中，则同样的行为也处于活动状态，但随后又存在一条规则。
如果至少有两个引号，请首先删除最后一个引号之后的所有字符。
使用引号内的文本，并使用“空格”规则。

样本。

set    "   abc def ghi"  junk junk
*** 1. removes the junk 
set    "   abc def ghi"
*** 2. removes the quotes
set       abc def ghi
*** 3. removes all after the last space, and the trailing spaces
set abc def
*** Search all variables beginning with abc def

Answer 2

我也喜欢问这种问题！ :)

这是我想出的另一个可能的解决方案...使用 SET 本身来测试是否存在，并使用 ERRORLEVEL 结果：

set "A B=foo"
set A B >nul 2>nul&& echo 1. This works
set "A B ">nul 2>nul&& echo 2. This works

set "A weird & "complex" variable=foo"
set A weird ^& "complex" variable >nul 2>nul&& echo 3. This works
set "A weird & "complex" variable ">nul 2>nul&& echo 4. This works

请注意，只有当您的变量是唯一的（即没有变量）时，这才有效name 是另一个的前缀。否则，您将面临误报的风险，因为 SET 的默认行为是显示以您传递的参数开头的所有变量。如果是这种情况，您可以使用 findstr 过滤结果：

set "A B="
set "A B C=foo"
set "A B ">nul 2>nul&& echo 5. Failed (false positive)
set "A B "|findstr /B /L /C:"A B=" >nul||echo 6. This works (no false positive)

此外，变量名称后面的单个尾随空格似乎是必需的。如果没有它，SET 经常会错误地解析输入。奇怪的是，如果您在“2>nul”和“&&”之间添加额外的空格如果#3它停止工作（除非你删除“>nul”之前的空格）......很奇怪。

Answer 3

另一种方法是将其重新分配给另一个变量（没有空格的变量）并测试该。参见这里：

rem Prepare ONLY variable 'a b'
set "a b=123"
echo [a b]=%a b%

rem This will ouput: [a b] is defined
set var=%a b%
if defined var (
  echo [a b] is defined
) else (
  echo [a b] is not defined
)

rem This will output: [c d] is not defined
set var=%c d%
if defined var (
  echo [c d] is defined
) else (
  echo [c d] is not defined
)

Answer 4

如果需要的话，我通过将标志定义为 TRUE 来做到这一点......

rem /* sample code */
set VAR_SET=
if <some condition> set VAR_SET=TRUE&set VAR=this data has spaces

rem /* test for VAR_SET using 'if defined' */
if defined VAR_SET (
  rem /* do something with the other data in the variable %VAR% */
)

rem /* clear the flag */
set VAR_SET=